6
$\begingroup$

I need to get the neighboring vertices and incident edges from a vertex in a graph. I assume NeighborhoodVertices (from the GraphUtilities package) can be used for the former. Anything better?

Or given something like {1 \[UndirectedEdge] 2, 2 \[UndirectedEdge] 3, 3 \[UndirectedEdge] 1}, how to directly get these information? Can I do list matching to some pattern?

$\endgroup$
10
$\begingroup$

A random graph

 g = RandomGraph[{15, 35}, VertexLabels -> "Name", PlotRangePadding -> .2]

enter image description here

Edges for the vertex 4:

 EdgeList[g, 4 \[UndirectedEdge] _]

Result:

enter image description here

Now vertexes around vertex4:

 VertexList[NeighborhoodGraph[g, 4]]

Result:

 {4, 14, 11, 6, 7, 9, 13, 15}

Illustration:

  HighlightGraph[g, NeighborhoodGraph[g, 4]]

enter image description here

There are many other ways. You could also use AdjacencyMatrix to get all that info.

$\endgroup$
  • 1
    $\begingroup$ yes, NeighborhoodVertices[g, 4, 1] can also get the same list with shorter typing. :) $\endgroup$ – Qiang Li Feb 17 '12 at 22:41
  • $\begingroup$ @QiangLi Only if you use GraphUtilities package - which I do not. ;-) I use built in Graph functionality. $\endgroup$ – Vitaliy Kaurov Feb 17 '12 at 22:47
  • $\begingroup$ True. :) +1 Thank you. $\endgroup$ – Qiang Li Feb 17 '12 at 22:55
0
$\begingroup$
SeedRandom[1]
g = RandomGraph[{15, 35}, VertexLabels -> "Name",  PlotRangePadding  -> .2];

Neighboring edges can also be obtained using IncidenceList:

IncidenceList[g, 4]

{2 <-> 4, 4 <-> 9, 4 <-> 10, 4 <-> 13, 4 <-> 14}

Neighboring vertices can be obtained using VertexList or VertexComponent on the output of IncidenceList

neighborhoodVerticesAndEdges = {VertexList@#, #} &@IncidenceList[g, 4]

{{2, 4, 9, 10, 13, 14}, {2 <-> 4, 4 <-> 9, 4 <-> 10, 4 <-> 13, 4 <-> 14}}

{Sort@VertexComponent[#, 4], #} &@IncidenceList[g, 4] == neighborhoodVerticesAndEdges

True

or using AdjacencyList:

{Union[AdjacencyList@##, {#2}], IncidenceList@##} &[g, 4]  == neighborhoodVerticesAndEdges

True

Row[{g, HighlightGraph[g, Join @@ neighborhoodVerticesAndEdges]}]

enter image description here

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.