6
$\begingroup$

Given a variable $y_i$, normally distributed with 0 mean and $σ_y$ standard deviation

$y_i$ ~ NormalDistribution[0,$σ_y$ ]

I want to obtain with Mathematica:

  1. The distribution of: $x = \bar{y} = \frac {\sum_{i=1}^ny_i}{n}$

  2. The joint distribution of $ (x,y_i )$

$\endgroup$
  • 5
    $\begingroup$ What have you tried? For example, have you seen the documentation on TransformedDistribution and ProbabilityDistribution? $\endgroup$ – JimB Mar 24 at 16:58
  • $\begingroup$ @JimB . I tried this TransformedDistribution[Sum[y, {i, n}]/n, y \[Distributed] NormalDistribution[0, \[Sigma]y]]. The result is NormalDistribution[0, \[Sigma]y]. However, the correct result should be NormalDistribution[0, \[Sigma]y / Sqrt[n]] $\endgroup$ – Andrea2810 Mar 24 at 17:42
  • 1
    $\begingroup$ You need to "index" the variable y or else Mathematica thinks it is a single variable. $\endgroup$ – JimB Mar 24 at 22:04
9
$\begingroup$

I don't know how to get Mathematica to get the joint distribution explicitly for a general value of $n$ but here is how one can easily see the pattern to figure out the general solution.

First the distribution of the mean:

marginalDistribution = TransformedDistribution[Sum[y[i], {i, n}]/n, 
  Table[y[i] \[Distributed] NormalDistribution[0, \[Sigma]], {i, n}], 
  Assumptions -> \[Sigma] > 0]
{#, marginalDistribution/.n->#} &/@Range[2,10]

$$ \begin{array}{cc} 2 & \text{NormalDistribution}\left[0,\frac{\sigma }{\sqrt{2}}\right] \\ 3 & \text{NormalDistribution}\left[0,\frac{\sigma }{\sqrt{3}}\right] \\ 4 & \text{NormalDistribution}\left[0,\frac{\sigma }{2}\right] \\ 5 & \text{NormalDistribution}\left[0,\frac{\sigma }{\sqrt{5}}\right] \\ 6 & \text{NormalDistribution}\left[0,\frac{\sigma }{\sqrt{6}}\right] \\ 7 & \text{NormalDistribution}\left[0,\frac{\sigma }{\sqrt{7}}\right] \\ 8 & \text{NormalDistribution}\left[0,\frac{\sigma }{2 \sqrt{2}}\right] \\ 9 & \text{NormalDistribution}\left[0,\frac{\sigma }{3}\right] \\ 10 & \text{NormalDistribution}\left[0,\frac{\sigma }{\sqrt{10}}\right] \\ \end{array} $$

So we see that the marginal distribution of $\bar{y}$ is

NormalDistribution[0, σ/Sqrt[n]]

The joint distribution of $\bar{y}$ and, say, $y_1$ is given by

jointDistribution = TransformedDistribution[{y[1], Sum[y[i], {i, n}]/n}, 
  Table[y[i] \[Distributed] NormalDistribution[0, \[Sigma]], {i, n}]]
{#, jointDistribution /. n -> #} & /@ Range[2, 10] // TableForm

$$ \begin{array}{cc} 2 & \text{MultinormalDistribution}\left[\{0,0\},\left( \begin{array}{cc} \sigma ^2 & \frac{\sigma ^2}{2} \\ \frac{\sigma ^2}{2} & \frac{\sigma ^2}{2} \\ \end{array} \right)\right] \\ 3 & \text{MultinormalDistribution}\left[\{0,0\},\left( \begin{array}{cc} \sigma ^2 & \frac{\sigma ^2}{3} \\ \frac{\sigma ^2}{3} & \frac{\sigma ^2}{3} \\ \end{array} \right)\right] \\ 4 & \text{MultinormalDistribution}\left[\{0,0\},\left( \begin{array}{cc} \sigma ^2 & \frac{\sigma ^2}{4} \\ \frac{\sigma ^2}{4} & \frac{\sigma ^2}{4} \\ \end{array} \right)\right] \\ 5 & \text{MultinormalDistribution}\left[\{0,0\},\left( \begin{array}{cc} \sigma ^2 & \frac{\sigma ^2}{5} \\ \frac{\sigma ^2}{5} & \frac{\sigma ^2}{5} \\ \end{array} \right)\right] \\ 6 & \text{MultinormalDistribution}\left[\{0,0\},\left( \begin{array}{cc} \sigma ^2 & \frac{\sigma ^2}{6} \\ \frac{\sigma ^2}{6} & \frac{\sigma ^2}{6} \\ \end{array} \right)\right] \\ 7 & \text{MultinormalDistribution}\left[\{0,0\},\left( \begin{array}{cc} \sigma ^2 & \frac{\sigma ^2}{7} \\ \frac{\sigma ^2}{7} & \frac{\sigma ^2}{7} \\ \end{array} \right)\right] \\ 8 & \text{MultinormalDistribution}\left[\{0,0\},\left( \begin{array}{cc} \sigma ^2 & \frac{\sigma ^2}{8} \\ \frac{\sigma ^2}{8} & \frac{\sigma ^2}{8} \\ \end{array} \right)\right] \\ 9 & \text{MultinormalDistribution}\left[\{0,0\},\left( \begin{array}{cc} \sigma ^2 & \frac{\sigma ^2}{9} \\ \frac{\sigma ^2}{9} & \frac{\sigma ^2}{9} \\ \end{array} \right)\right] \\ 10 & \text{MultinormalDistribution}\left[\{0,0\},\left( \begin{array}{cc} \sigma ^2 & \frac{\sigma ^2}{10} \\ \frac{\sigma ^2}{10} & \frac{\sigma ^2}{10} \\ \end{array} \right)\right] \\ \end{array} $$

So the general distribution is a multivariate normal

MultinormalDistribution[{0, 0}, {{σ^2, σ^2/n}, {σ^2/n, σ^2/n}}]

The general form of the joint density function can then be found with

FullSimplify[PDF[MultinormalDistribution[{0, 0}, {{σ^2, σ^2/n}, {σ^2/n, σ^2/n}}], {y, ybar}],
  Assumptions -> {σ > 0, n > 1}]

$$\frac{n e^{-\frac{n \left(n \text{ybar}^2+y^2-2 y \text{ybar}\right)}{2 (n-1) \sigma ^2}}}{2 \pi \sqrt{n-1} \sigma ^2}$$

$\endgroup$
  • $\begingroup$ Anyway, I like your answer! I'll have to look at it to understand (not obvious (to me) that this would be the solution). $\endgroup$ – mjw Mar 24 at 22:38
  • $\begingroup$ @mjw Good. Answers should always be scrutinized and challenged if desired. $\endgroup$ – JimB Mar 24 at 22:40
  • $\begingroup$ Nice! In addition to trying to understand the technique, I checked the marginal integrals. Looks great! $\endgroup$ – mjw Mar 25 at 1:13
1
$\begingroup$

Here is the distribution of $x=\overline{y}$ (Part I of your question):

a[n_] := Table[y[k] \[Distributed] NormalDistribution[0, \[Sigma]], {k, 1, n}]; 
p[n_] := TransformedDistribution[Sum[y[k]/n, {k, n}], a[n]];

Now

x \[Distributed] p[5] (* n=5, for example *)

The result is

x \[Distributed] NormalDistribution[0, Abs[\[Sigma]]/Sqrt[5]]
$\endgroup$
  • $\begingroup$ I am not sure, but shouldn't be n instead of 5 here TransformedDistribution[Sum[y[k]/n, {k, 5}], a] ? And what if I want to leave n, without assigning a value to n? Thanks @mjw $\endgroup$ – Andrea2810 Mar 24 at 21:13
  • $\begingroup$ Oh yes, you are right! I started with 10 and changed to five as I was trying it out. I'll fix it ... Thanks! $\endgroup$ – mjw Mar 24 at 21:18
  • $\begingroup$ Let's go with five because it is clearer. The result is NormalDistribution[0,\[Sigma]/Sqrt[5]]. Not sure why Mathematica puts Abs[] around $\sigma$. Obviously, $\sigma>0$. $\endgroup$ – mjw Mar 24 at 21:22
  • $\begingroup$ Yes, sure it is clearer. Do you have any idea of how can I use n as a parameter, without assigning a value to n? $\endgroup$ – Andrea2810 Mar 24 at 21:24
  • $\begingroup$ a[n_] = Table[y[k] \[Distributed] NormalDistribution[0, \[Sigma]], {k, 1, n}]; $\endgroup$ – mjw Mar 24 at 21:25

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.