10
$\begingroup$

What is a simple code to plot a surface shaped like a tornado? Any help is welcome.

$\endgroup$
17
$\begingroup$

My quick go at it:

ContourPlot3D[
  (x - z/5 Cos[\[Pi] z])^2 + (y - z/5 Sin[\[Pi] z])^2 == (z/4)^2
  , {x, -1, 1}, {y, -1, 1}, {z, 0, 2}
  , Mesh -> None, Axes -> False, Boxed -> False
  , PlotTheme -> "ThickSurface", ContourStyle -> RGBColor[0.41, 0.5, 0.63]
]

Tornado

$\endgroup$
17
$\begingroup$

I like "surface synthesis" questions. Here's a simple-minded model that combines an Archimedean spiral with a power law curve:

With[{h = 1/10, n = 24, c = 4, p = 2/3},
     ParametricPlot3D[{t (h Cos[n t] + Cos[v]), t (h Sin[n t] + Sin[v]), (c t)^p},
                      {t, 0, 3}, {v, 0, 2 π}, Axes -> None, Boxed -> False,
                      Lighting -> "Neutral", Mesh -> False, PlotPoints -> 85,
                      PlotStyle -> Opacity[3/4, Black], ViewPoint -> {3.2, -1.6, 1.}]]

tornado?

Adjust parameters as seen fit.

$\endgroup$
  • 5
    $\begingroup$ (I should prolly do a cartoon of the "tornado" moving about in a random walk...) $\endgroup$ – J. M. is away Mar 22 at 12:38

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.