2
$\begingroup$

Let $$f(x_1, x_2, x_3, x_4) := \frac{x_1^{-3} x_2^{-2} x_3^{-1}}{(1 - x_1^2) (1 -x_1^2 x_2^2) (1 - x_1^2 x_2^2 x_3^2) (1 - x_1^2 x_2^2 x_3^2 x_4^2)}.$$ I am trying to compute $$\sum_{w\in S_4} (-1)^{\overline{w}} w(f),$$ where $\overline{w}$ is the parity of the permutation element $w$ (it's the number of transpositions when $w$ is written as a product of such), and $w$ is acting $f$ via the indices of the variables $x_i$.

I have this code

f[x1_, x2_, x3_, x4_] := (x1^-3 x2^-2 x3^-1)/((1 - x1^2) (1 - x1^2 x2^2) (1 - x1^2 x2^2 x3^2)(1 - x1^2 x2^2 x3^2 x4^2));

Total[Permute[g @@ Array[Subscript[x, #] &, 4], #] & /@GroupElements[SymmetricGroup[4]] /. g -> f]

but I am not sure how to incorporate the Signature[] of some permutation element so that it coincides with Permute in the code.

$\endgroup$
3
$\begingroup$

The problem is that Signature wants to operate on expressions and interprets each Cycles[...] object as a list of length 1. You can convert Cycles objects to list with PermutationsList and apply Signature afterwards.

With[{xx = Array[Subscript[x, #] &, 4]},

 Sum[
  Signature[PermutationList[σ, 4]] f @@ Permute[xx, σ],
  {σ, GroupElements[SymmetricGroup[4]]}
  ]

 ]

Alternatively, you may skip the group hokus-pokus and use Permutations:

With[{xx = Array[Subscript[x, #] &, 4]},

 Sum[
  Signature[p] f @@ xx[[p]],
  {p, Permutations[Range[4]]}
  ]

 ]
$\endgroup$
  • $\begingroup$ Nice. Thank you. This is very helpful! $\endgroup$ – Mee Seong Im Mar 20 at 18:24
  • 1
    $\begingroup$ You're welcome. $\endgroup$ – Henrik Schumacher Mar 20 at 18:27

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.