How can I get a function that gives the following output?
listX = {a, b, c, d}
numberX = 3
myDuplicatesList[listX, numberX]
{{a,a,a},{b,b,b},{c,c,c},{d,d,d}}
$\begingroup$
$\endgroup$
1
-
6$\begingroup$ Wolfram Challenges. $\endgroup$– J. M.'s lack of A.I. ♦Mar 8, 2019 at 14:23
Add a comment
|
8 Answers
$\begingroup$
$\endgroup$
I like using KroneckerProduct for problems like this:
KroneckerProduct[listX, ConstantArray[1, numberX]]
{{a, a, a}, {b, b, b}, {c, c, c}, {d, d, d}}
The KroneckerProduct approach should be much faster than the others for large vectors.
answered Mar 8, 2019 at 15:39
$\begingroup$
$\endgroup$
2
Alternatively:
listX = {a, b, c};
numberX = 3;
Table[ConstantArray[i, numberX], {i, listX}]
{{a, a, a}, { b, b, b}, {c, c, c}}
Or:
listX = {a, b, c, d};
numberX = 3;
Transpose@Table[i, {numberX}, {i, listX}]
-
1
-
1$\begingroup$ No need to use Transpose, just invert the order of the arguments: Table[i, {i,listX}, numberX] $\endgroup$– jjagmathMar 9, 2019 at 12:18
$\begingroup$
$\endgroup$
Array[listX &, numberX, 1, Transpose[{##}] &]
{{a, a, a}, {b, b, b}, {c, c, c}, {d, d, d}}
ArrayPad[List /@ listX, {0, {0, numberX - 1}}, "Fixed"]
{{a, a, a}, {b, b, b}, {c, c, c}, {d, d, d}}
PadRight[{#}, numberX, "Fixed"] & /@ listX )* or *)
PadRight[List /@ listX, {Automatic, numberX}, "Fixed"]
{{a, a, a}, {b, b, b}, {c, c, c}, {d, d, d}}
TensorProduct[listX, Array[1 &, numberX]]
{{a, a, a}, {b, b, b}, {c, c, c}, {d, d, d}}
ArrayResample[listX, Scaled @ numberX , "Bin", Resampling -> "NearestLeft"]
{a, a, a, b, b, b, c, c, c, d, d, d}
Partition[%, numberX]
{{a, a, a}, {b, b, b}, {c, c, c}, {d, d, d}}
$\begingroup$
$\endgroup$
one way might be
listX = {a, b, c, d}
numberX = 3
Transpose[{listX}].{Table[1, {numberX}]}
$\begingroup$
$\endgroup$
Transpose@ConstantArray[listX, numberX]
{{a, a, a}, {b, b, b}, {c, c, c}, {d, d, d}}
$\begingroup$
$\endgroup$
Yet Another Way:
Flatten[ConstantArray[{listX}, numberX], {2, 3}]
And another (the last argument 1 is necessary only when listX is not a flat list):
Outer[Times, listX, ConstantArray[1, numberX], 1]
answered Mar 8, 2019 at 23:50
$\begingroup$
$\endgroup$
Transpose[{listX}[[ConstantArray[1, numberX]]]]
answered Mar 8, 2019 at 14:21
$\begingroup$
$\endgroup$
listX = {a, b, c, d};
numberX = 3;
Using SequenceReplace:
SequenceReplace[listX, {g_} :> Table[g, numberX]]
Using Replace:
listX // Replace[#, a_ :> Table[a, numberX], {1}] &
{{a, a, a}, {b, b, b}, {c, c, c}, {d, d, d}}
