# Infinite sum + integral

I have the following sum + integral to solve: $$\int_0^{\infty}dt\, t^{\frac{m-3}{2}} e^{-t(a^2+b^2)} \sum_{n=-\infty}^{\infty} e^{-t(c^2 n^2 +2bcn)}$$

My try:

Refine[
Integrate[t^{(m - 3)/2} Exp[-t (a^2 + b^2)] Sum[
Exp[-t (c^2 n^2 + 2 b c n)], {n, -Infinity, Infinity}], {t,0,Infinity}],
{Element[{a, b, c}, Reals], Element[m, Integers], m > 0}]

where $$a,b,c\in\mathrm{R}$$, $$m\in\mathrm{N^+_0}$$. So far, this input gives an output with an integral (and an EllipticTheta function):

$$\text{Integrate}\left[\frac{\sqrt{\pi } t^{\frac{m-3}{2}-\frac{1}{2}} e^{b^2 t-t \left(a^2+b^2\right)} \vartheta _3\left(\frac{b \pi }{c},e^{-\frac{\pi ^2}{c^2 t}}\right)}{\left| c\right| },\{t,0,\infty \},\text{Assumptions}\to m\in \mathbb{Z}\land (a|b|c)\in \mathbb{R}\land m>0\right]$$

Is it possible to do the sum & integration to receive a closed form, at least for some particular values of $$m$$, like $$m=0,1,2,3$$? How to change the input in order to achieve that?

I'll welcome any comments on how to improve this question (and its title).

• Have you tried plugging in those values of $m$ in your code and seeing what happens? – MarcoB Feb 28 at 15:28

Making unsubstantiated use of Fubini's theorem or whatever its discrete equivalent is, let's interchange the sum and the integral:

$$\sum_{n=-\infty}^{\infty} \int_0^{\infty}dt\, t^{\frac{m-3}{2}}e^{-t(a^2+b^2)}e^{-t(c^2n^2+2bcn)}$$

First doing the integration:

Assuming[Element[a | b | c, Reals] && Element[m | n, Integers],
Integrate[t^((m - 3)/2) Exp[-t (a^2 + b^2)] Exp[-t (c^2 n^2 + 2 b c n)],
{t, 0, ∞}] // FullSimplify]

ConditionalExpression[(a^2 + (b + c n)^2)^((1 - m)/2) Gamma[1/2 (-1 + m)], m > 1]

Then we do the sum for a specific value of $$m\ge2$$:

With[{m = 2}, Sum[(a^2 + (b + c n)^2)^((1 - m)/2) Gamma[1/2 (-1 + m)], {n, -∞, ∞}]]

Sum doesn't converge.

With[{m = 3}, Sum[(a^2 + (b + c n)^2)^((1 - m)/2) Gamma[1/2 (-1 + m)], {n, -∞, ∞}]]

$$\frac{\pi \left(\left\lfloor \frac{2 \arg (a-i b)-2 \arg (c)+\pi }{4 \pi }\right\rfloor +\left\lfloor \frac{-2 \arg (a-i b)+2 \arg (c)+\pi }{4 \pi }\right\rfloor \right)}{a c}+\frac{\pi \coth \left(\frac{\pi a-i \pi b}{c}\right)}{2 a c}+\frac{\pi \coth \left(\frac{\pi a+i \pi b}{c}\right)}{2 a c}$$

With[{m = 4}, Sum[(a^2 + (b + c n)^2)^((1 - m)/2) Gamma[1/2 (-1 + m)], {n, -∞, ∞}]]

(no closed form)

With[{m = 5}, Sum[(a^2 + (b + c n)^2)^((1 - m)/2) Gamma[1/2 (-1 + m)], {n, -∞, ∞}]]

$$\frac{\pi \left\lfloor \frac{2 \arg (a-i b)-2 \arg (c)+\pi }{4 \pi }\right\rfloor }{2 a^3 c}+\frac{\pi \left\lfloor \frac{-2 \arg (a-i b)+2 \arg (c)+\pi }{4 \pi }\right\rfloor }{2 a^3 c}+\frac{\pi \coth \left(\frac{\pi a-i \pi b}{c}\right)}{4 a^3 c}+\frac{\pi \coth \left(\frac{\pi a+i \pi b}{c}\right)}{4 a^3 c}+\frac{\pi ^2 \text{csch}^2\left(\frac{\pi a-i \pi b}{c}\right)}{4 a^2 c^2}+\frac{\pi ^2 \text{csch}^2\left(\frac{\pi a+i \pi b}{c}\right)}{4 a^2 c^2}$$

etc. It seems that this method gives closed-form solutions for odd $$m\ge3$$.