Putting a vertical line in each Histogram using GraphicsGrid

Question

I'm using GraphicsGrid to show several histograms.

In each histogram, I would like to show 2 vertical lines on the 2.5 and 97.5 percentiles. If I had an isolated histogram I would use Line, and Show. However, I have no idea how to proceed with a GraphicsGrid...

Answer 1

You can use GridLines combined with the option Method ->{"GridLinesInFront" -> True}:

SeedRandom[1]
{data1, data2} = RandomVariate[NormalDistribution[#, 1], 500] & /@ {2, 4};
GraphicsGrid[{Histogram[#, ImageSize -> 300, 
     GridLines -> {Thread[{Quantile[#, {.025, .975}], 
         Directive[Opacity[1], Thick, #] & /@ {Red, Blue}}], None}, 
     Method -> {"GridLinesInFront" -> True}] & /@ {data1, data2}}]

Answer 2

Combining two sets of graphics objects with Show in a graphics grid is not difficult as long as the sets are compatible. That means, at least, all the objects in both lists should be plotted in the same coordinate system and have the same image size.

Here is an example using some graphics I contrived.

Draw random group of $n$ circles

circles[n_] :=
  Module[{r, cntr},
    r := RandomReal[.25];
    cntr := RandomReal[1, {2}];
    Graphics[
      Table[{EdgeForm[Black], Hue[RandomReal[]], Disk[cntr, r]}, n],
      PlotRange -> {{0, 1}, {0, 1}},
      PlotRangeClipping -> True,
      Frame -> True]]

Draw two random vertical lines with the left one red and the right one blue.

lines[] :=
  Module[{lf, rt},
    lf := With[{x = RandomReal[.48]}, {Red, Line[{{x, 0}, {x, 1}}]}];
    rt := With[{x = RandomReal[{.52, 1}]}, {Blue, Line[{{x, 0}, {x, 1}}]}];
    Graphics[{lf, rt},
      PlotRange -> {{0, 1}, {0, 1}},
      PlotRangeClipping -> True,
      Frame -> True]]

Now the following simple function will combined any two lists of graphics that are compatible in sense mentioned in the preamble to this answer. The rather elaborate argument patterns on the lefthand side of the SetDelayed expression represent my attempt to enforce the compatibility of the arguments.

makeGrid[g1 : {_Graphics ..}, g2 : {_Graphics ..}, rows_Integer /; rows > 0] /; 
    Length[g1] == Length[g2] && Mod[Length[g1], rows] == 0 :=
  GraphicsGrid @ Apply[Show, Partition[Transpose[{g1, g2}], rows], {2}]

So let's make a 4 x 4 graphics grid from a list of four circles groups and a list of four pairs of vertical lines.

SeedRandom[4];
makeGrid[Table[circles[8], 4], Table[lines[], 4], 2]