1
$\begingroup$

I'm trying to solve a system of equations. The problem I'm encountering is that one equation is transcendental and Solve is unable to find a solution for it, so can't find a solution for the system. Is there any way to solve this system?

Smallest Working Example:

BearLM = {{1, 0, 0, 0, 0}, {0, 1, 0, 0, 0}, {0, 10^7, 1, 0, 0}, {-500,
     0, 0, 1, 0}, {0, 0, 0, 0, 1}};
RollLM[q_] = {{1, 20, Power[20, 2]/(2* 4.2*10^13), Power[20, 3]/(
    6 *4.2*10^13), q Power[20, 4]/(24* 4.2*10^13)}, {0, 1, 20/( 
    4.2*10^13), Power[20, 2]/(2* 4.2*10^13), 
    q Power[20, 3]/(6 *4.2*10^13)}, {0, 0, 1, 20, 
    q Power[20, 2]/2}, {0, 0, 0, 1, q 20}, {0, 0, 0, 0, 1}} ;
Vec11 = {vA, \[CurlyPhi]A, 0, 0, 1};
Vec12 = BearLM. Vec11; 
VecList1 = {Vec12};
Vec21 = {vS, \[CurlyPhi]S, 0, 0, 1};
Vec22 = BearLM.Vec21;
VecList2 = {Vec22};
Gls := {
   {vAR, \[CurlyPhi]AR, FQAR, MbAR, 1} == 
    RollLM[qW + 1].Last[VecList1], 
   {vSR, \[CurlyPhi]SR, FQSR, MbSR, 1} == RollLM[-qW].Last[VecList2],
   vAR - vSR == 8.5*10^(-6) qW*Log[12000/(4.6*10^(-5) qW)]
   };

Res = Solve[
   Gls, {vAR, \[CurlyPhi]AR, FQAR, MbAR, vSR, \[CurlyPhi]SR, FQSR, 
    MbSR, qW}][[1]]
$\endgroup$
3
$\begingroup$
eqs = Flatten[Thread /@ Gls]
vars = {vAR, \[CurlyPhi]AR, FQAR, MbAR, vSR, \[CurlyPhi]SR, FQSR, MbSR, qW}

Solve all but the last equations (linear system) in terms of all vars but qW:

partial = Solve[eqs[[1 ;; -2]], vars[[1 ;; -2]]];

The remaining equation is:

last = Simplify[eqs[[-1, 1]] - eqs[[-1, 2]] /. First[partial]]

It can apparently be handled by Solve now :

qwsol = Solve[last == 0, vars[[-1]]]

Quick check:

FullSimplify[last /. First[qwsol]] /. {vA -> 1.1, vS -> 2.2, \[CurlyPhi]A -> 3.3, \[CurlyPhi]S -> -4.4 }
(* -5.9992*10^-12 *)
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.