Finding where a specific number appears in an expression

Question

I would like to see how many times (and where) the number "91" appear in a set of formulae.

I thought of using Position[expr , 91 , Infinity], but it seems not to be working in this simple example:

Position[{Log[Sqrt[1 + I Sqrt[-1 + (4 mm)/91]]]}, 91, ∞]

which gives

{}

Why?

Answer 1

Try this:

expr = Log[Sqrt[1 + I Sqrt[-1 + (4 mm)/91]]];
Position[expr, f_[x_, 91] | f_[91, x_]]

(*  {{1, 1, 2, 2, 1, 2, 1}}   *)

Have fun!

Answer 2

expr = {Log[Sqrt[1 + I Sqrt[-1 + (4 mm)/91]]]};

If you look at the FullForm of the expression, you see that 91 appears only inside Rational

expr // FullForm

Since Rational is an atomic element (Atomic Elements of Expressions), the 91 is not accessible by Position. However, you can see the position of the Rational containing 91 as shown by Alexei.

Position[expr, Rational[_, 91], ∞]

(* {{1, 1, 1, 2, 2, 1, 2, 1}} *)

There are no parts to an atomic expression.

Rational[4, 91][[-1]]

Answer 3

An alternative pattern to search through the atoms:

Position[Log[Sqrt[1 + I Sqrt[-1 + (4 mm)/91]]], _?AtomQ[___, 91, ___] | 91]

{{1, 1, 2, 2, 1, 2, 1}}

Also

Position[Log[Sqrt[1 + I Sqrt[-1 + (4 mm)/91]]], 
 TypeSystem`$AtomPattern[___, 91, ___] | 91]

{{1, 1, 2, 2, 1, 2, 1}}

Answer 4

Another approach would be to change the expression into a string and then locate the string "91" within that. For your example:

expr = {Log[Sqrt[1 + I Sqrt[-1 + (4 mm)/91]]]}; 
StringPosition[ToString[expr], "91"]
{{94, 95}}

Which shows that 91 occurs in the final two positions of the string.