Automatically rotate frame ticks labels

Question

Say in

ListPlot[Range[0, 1, 0.1], Frame -> True]

I want the tick marks on the vertical axis to be rotated 90 degrees. How to do it automatically, preserving the sub-ticks?

It's of course doable with explicitly given FrameTicks, but then the sub-ticks need to be specified and it gets cumbersome. I'm looking for something like FrameTicks(Labels) -> {{Rotated,Automatic},{Automatic,Automatic}}, or something similar to RotateLabel.

---

$Version

"10.4.1 for Linux x86 (64-bit) (April 11, 2016)"

Answer 1

ListPlot[Range[0, 1, 0.1], Frame -> True, 
 FrameTicks -> {{Charting`ScaledTicks["Linear"][##] /. 
      {a_?NumericQ, b_, c___} :> {a, Rotate[b, 90 Degree], c} &, Automatic}, 
    {Automatic, Automatic}}, 
 ImagePadding -> Scaled[.02]]

Also

ListPlot[Range[0, 1, 0.1], Frame -> True, 
 FrameTicks -> {{MapAt[Rotate[#, 90 Degree] &, 
    Charting`FindTicks[{0, 1}, {0, 1}][##], {All, 2}] &, Automatic}, 
   {Automatic, Automatic}},
  ImagePadding -> Scaled[.02]]

same picture

This works in

 $Version

"11.3.0 for Microsoft Windows (64-bit) (March 7, 2018)"