5
$\begingroup$

In functions like NonlinearModelFit I need to specify parameters with a symbol name. If I localize these parameters they get cluttered in the output (e.g."ParameterTable"):

{a, b, c, d} = {2, 30, 4, 0};
data = a PDF[NormalDistribution[b, c], Range@100] + 
   RandomReal[{-.01, .01}, 100];

fitFunc[a_, b_, c_, d_, x_] := a PDF[NormalDistribution[b, c], x] + d

fit[data_] := Module[{a, b, c, d, aStart, nlmf},
  aStart = Max@data;
  nlmf = NonlinearModelFit[data, 
    fitFunc[a, b, c, d, x], {{a, aStart}, {b, 30}, {c, 4}, {d, 0}}, x];
  nlmf["ParameterTable"]
  ]

fit@data

How can I avoid outputs like a$18554 in the the ParameterTable without using global symbol names for the parameters a, b, c, d inside NonlinearModelFit?

Improve this question
$\endgroup$
  • $\begingroup$ Do you care about the actual symbols used or just their appearance in the table? If the latter, you could use the package I posted here along with Block in place of Module. The parameters will all be renamed to things like TransformedParameter$4 but will still display as the original symbols. $\endgroup$ – Oleksandr R. Feb 5 '13 at 15:53
  • 1
    $\begingroup$ Could put the variable names in the input, as fit[data_,vars_] := Module[...] where you then use vars explicitly in the Module. $\endgroup$ – Daniel Lichtblau Feb 5 '13 at 15:54
  • $\begingroup$ Have you considered using Formal Symbols? $\endgroup$ – Mr.Wizard Feb 5 '13 at 16:42
  • 2
    $\begingroup$ Some reasonable starting values to use (instead of the hard-coded ones) are dStart = Min@data; bStart = Position[data, Max@data] // Flatten // Mean; cStart = Max[#] - Min[#] & @ Flatten[Position[data, Alternatives @@ Select[data, 2 (# - dStart ) >= (Max@data - dStart) &]]] /2; aStart = (Max@data - dStart) cStart; $\endgroup$ – whuber Feb 5 '13 at 17:03
1
$\begingroup$

One brute force way is to convert parameters to strings:

fit[data_] := 
  Module[{a, b, c, d, aStart, nlmf}, aStart = Max@data;
      nlmf = NonlinearModelFit[data, fitFunc[a, b, c, d, x], 
            {{a, aStart}, {b, 30}, {c, 4}, {d, 0}}, x];
       nlmf["ParameterTable"] /. {a -> "a", b -> "b", c -> "c", d -> "d"}
  ]
Improve this answer
$\endgroup$
  • $\begingroup$ This is not as elegant as I had hoped. But it is a working solution! Maybe I will ask for a more general solution in another question. Thx! $\endgroup$ – grbl Feb 6 '13 at 15:26

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.