2
$\begingroup$

I was playing around with Manipulate to demonstrate simple geometric idea of conic sections and put this little sample together. When i move the slider it moves my plane, which is what I expect. However, when I let go of the slider, the graphics are rescaled. So how I stop that? I have set the PlotRange and AspectRatio, so I don't understand why the scale is changing.

Manipulate[
  plot = Plot3D[n, {x, -1, 1}, {y, -1, 1},
    AspectRatio->1, PlotRange->{{-1, 1}, {-1, 1}}, Mesh->False];
  cone = Graphics3D[{Opacity[0.3], Cone[{{0, 0, -1}, {0, 0, 1}}, 1]},
    PlotRange->{{-1, 1}, {-1, 1}}, AspectRatio->1];
  Show[{plot, cone}, AspectRatio->1],
  {{n, 0}, -1, 1}]
Improve this question
$\endgroup$
0

2 Answers 2

Reset to default
3
$\begingroup$ 
 Manipulate[
 plot = Plot3D[n, {x, -1, 1}, {y, -1, 1}, BoxRatios -> 1, 
 PlotRange -> {{-1, 1}, {-1, 1}, {-1, 1}}, Mesh -> False]; 
 cone = Graphics3D[{Opacity[0.3], Cone[{{0, 0, -1}, {0, 0, 1}}, 1]}, 
 PlotRange -> {{-1, 1}, {-1, 1}, {-1, 1}}, BoxRatios -> 1]; 
 Show[{plot, cone}, BoxRatios -> 1], {{n, 0}, -1, 1}]

enter image description here

Update: Shorter version (that also avoids the constant dynamic updates in the previous version):

 Manipulate[Show[Plot3D[n, {x, -1, 1}, {y, -1, 1}, BoxRatios -> 1,
 PlotRange -> {-1, 1}, Mesh -> False],
  Graphics3D@{Opacity[0.3], Cone[{{0, 0, -1}, {0, 0, 1}}, 1]}],
{{n, 0}, -1, 1}]

or

 Manipulate[ Graphics3D[{LightBlue, 
   Polygon[{{-1, -1, n}, {-1, 1, n}, {1, 1, n}, {1, -1, n}}],
  Opacity[0.3], Cone[{{0, 0, -1}, {0, 0, 1}}, 1]},
  PlotRange -> {-1, 1}, BoxRatios -> 1],
 {{n, 0}, -1, 1}]
Improve this answer
$\endgroup$
4
  • $\begingroup$ Excellents. Thanks for help. $\endgroup$
    – David McHarg
    Feb 4, 2013 at 15:43
  • $\begingroup$ @DavidMcHarg, my pleasure. Welcome to Mathematica.SE. $\endgroup$
    – kglr
    Feb 4, 2013 at 15:44
  • $\begingroup$ Never new about Initialization option, thanks for that. $\endgroup$
    – David McHarg
    Feb 4, 2013 at 17:21
  • $\begingroup$ @Nasser, good point; added simpler/shorter versions that eliminate the need for Show. $\endgroup$
    – kglr
    Feb 4, 2013 at 17:28
3
$\begingroup$

I updated my example to allow both the plane to be moved up/down and to change the inclination of the plane. I nice little example for conic sections, good for kids to see this stuff in action.

Manipulate[plot = Plot3D[ n x+m,{x,-1,1},{y,-1,1},
BoxRatios->1,PlotRange->{{-1,1},{-1,1},{-1,1}},Mesh->False];
cone = Graphics3D[{Opacity[0.3],Cone[{{0,0,-1},{0,0,1}},1]},
PlotRange->{{-1,1},{-1,1},{-1,1}},BoxRatios->1];
Show[{plot,cone},BoxRatios->1],
{{n,0,"Angle"},-1,1},{{m,0,"Intersection"},-1,1}
]

Conic sections

Improve this answer
$\endgroup$
2
  • $\begingroup$ nice :)) ... +1. (You might consider adding TrackedSymbols -> {n, m}to avoid the constant flickering.) $\endgroup$
    – kglr
    Feb 4, 2013 at 17:56
  • $\begingroup$ also for kids to enjoy: ice cream cones :) $\endgroup$
    – kglr
    Feb 4, 2013 at 18:05

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.