Plotting massive amount of data

Question

I have to plot a huge amount of data. I have only one file, I've already imported it. The file contains the following:

48 separate smaller fractions.

Every fraction begins with six numbers (which are unnecessary, for now) and it is followed by four larger vectors, the first three has nineteen (x,y) elements and the last one has eightteen (x,y) pairs inside them.

It looks something like this:

data={{a,b,c,d,e,f,{{x1,y1},{x2,y2},...,{x19,y19}},{...},{...},{...}},{a1,b1,...}}

I'd like to plot every vector ({{x1,y1},{x2,y2},...,{x19,y19}}) in a separate subplot with ListLinePlot, but all four in one row. For all of the 48 fractions. So, as a result, the whole plot would contain 48 rows and 4 columns of subplots.

{a,b,c,d,e,f} are needed in naming every graph, but that's a separate problem.

I'm relatively new to Mathematica. Can anyone help me how to plot this monster?

Answer 1

Generate data in the same format as what you have:

gen[l_] := RandomFunction[RandomWalkProcess[.5], {0, l}]["Path"]
dat = Table[{1, 2, 3, 4, 5, 6, gen[19], gen[19], gen[19], gen[18]}, 
  48]

Plot:

plots = Map[ListLinePlot[#[[{7, 8, 9, 10}]], 
   PlotLabel -> #[[{1, 2, 3, 4, 5, 6}]]] &, dat]

Since you have all these, you may consider something like TabView[plots] to make it easier to see individual lists.

You may also want to do something like:

Grid[Partition[plots, 6]]

to display the data in a uniform grid, like so:

The upside to this is that the plots will more-or-less scale to fit into your notebook window.

It occurs to me that you may want 4 columns and 48 rows.

First we define a function to create plots with the same label (this is for each of the 4 vectors within each dataset):

p[dataarr_, label_] := Map[ListLinePlot[#, PlotLabel -> label] &, dataarr]

Now we use this function on all the 48 datasets:

plots = Map[p[#[[{7, 8, 9, 10}]], #[[{1, 2, 3, 4, 5, 6}]]] &, dat]

Then we can use Grid to display the data nicely: