Mathematica Stack Exchange is a question and answer site for users of Wolfram Mathematica. It only takes a minute to sign up.
Sign up to join this community
Assume that I have a table of complex functions like
Clear[p]
Clear[M]
M = 10;
G = Table[Sin[i p] + p I, {i, M}]
I want to ParametricPlot them in graphs, each graph contains only one of them. What should I edit in the following code
ParametricPlot[Evaluate[ReIm /@ G], {p, 0, 2},
AxesLabel -> (Style[#, 12, Bold] & /@ {Re, Im}),
PlotRange -> {{-1.2, 1.2}, {0, 2}}, ImageSize -> 600,
PlotLegends -> Placed[G, Right]]
Which plot them in the following single graph:
Thanks in advance.
plots = ParametricPlot[Evaluate[ReIm@#], {p, 0, 2},
AxesLabel -> (Style[#, 12, Bold] & /@ {Re, Im}),
PlotRange -> {{-1.2, 1.2}, {0, 2}}, ImageSize -> 600,
PlotLegends -> Placed[#, Right]] & /@ G;
Grid[Partition[plots, 2]]
PlotStyle -> ColorData[97, "ColorList"][[i]], refer to mathematica.stackexchange.com/questions/54629/…
$\endgroup$
Jan 18, 2019 at 21:55
If you only want to display one plot at a time, consider using Manipulate
Clear[p]
M = 10;
G = Table[Sin[i p] + p I, {i, M}];
Manipulate[
Legended[
ParametricPlot[
ReIm@G[[i]], {p, 0, 2},
AxesLabel -> (Style[#, 12, Bold] & /@ {Re, Im}),
PlotRange -> {{-1.2, 1.2}, {0, 2}},
ImageSize -> 300,
ColorFunction -> (ColorData["Rainbow"][#3] &)],
Labeled[
BarLegend[{"Rainbow", {0, 2}}],
Style["p", 12, Bold], Top]],
{{i, 5}, Range[Length[G]], ControlType -> SetterBar}]
