11
$\begingroup$

Can I hatch this region in any way?

Graphics[{
Circle[{0,0},10,{ArcCos[5/10],ArcCos[5Sqrt[3]/10]}],
Line[{{5Sqrt[3],5},{5Sqrt[3],-5}}],
Circle[{0,0},10,{-ArcCos[5/10],-ArcCos[5Sqrt[3]/10]}],
Line[{{5,-5Sqrt[3]},{5,5Sqrt[3]}}]
},
Axes->True,
AxesOrigin->{0,0}
]

enter image description here

EDIT

I want to define a region of a circle, because I want to determine the area of this region...

enter image description here

$\endgroup$
1
  • $\begingroup$ For what purpose? $\endgroup$ Jan 3 '19 at 19:10
19
$\begingroup$

Update: Version 12.1 comes with new directives PatternFilling and HatchFilling that can be use as the option setting for PlotStyle:

RegionPlot[reg, Mesh -> None, 
  PlotStyle -> PatternFilling["Diamond", ImageScaled[.025]], 
  BoundaryStyle -> Directive[Thick, Red], 
  Prolog -> {Thick, Circle[{0, 0}, 10]},
  PlotRangePadding -> Scaled[.05], PlotRange -> {-10, 10}]

enter image description here

RegionPlot[reg, Mesh -> None, 
 PlotStyle -> Directive[Gray, HatchFilling["Diagonal", 3, 5]], 
 BoundaryStyle -> Directive[Thick, Red], 
 Prolog -> {Thick, Circle[{0, 0}, 10]}, 
 PlotRangePadding -> Scaled[.05], PlotRange -> {-10, 10}, 
 PlotPoints -> 100]

enter image description here

Original answer:

reg = ImplicitRegion[x^2 + y^2 <= 100 && 5 <= x <= 5 Sqrt[3], {x, y}];
N[Area[reg]]

52.3599

Show[Graphics[{Gray, Circle[{0, 0}, 10]}, Axes -> True], 
 RegionPlot[reg, MeshFunctions -> {# + #2 &, # - #2 &}, 
  Mesh -> {50, 50}, MeshShading -> None, PlotStyle -> None, 
  BoundaryStyle -> Red]]

enter image description here

RegionPlot[x^2 + y^2 <= 100 && 5 <= x <= 5 Sqrt[3],{x, -10, 10}, {y, -10, 10}, 
 MeshFunctions -> {# + #2 &, # - #2 &}, Mesh -> {50, 50}, 
 MeshShading -> None, PlotStyle -> None, BoundaryStyle -> Red, 
 PlotPoints -> 90, Axes -> True, Epilog -> {Gray, Scale[Circle[], 10]}, 
 Frame -> False]

same picture

$\endgroup$
5
$\begingroup$
poly = MeshPrimitives[
    BoundaryDiscretizeRegion[
     RegionIntersection[
      Disk[],
      HalfPlane[{{5/10, 0}, {5/10, 1}}, {1, 0}],
      HalfPlane[{{5 Sqrt[3]/10, 0}, {5 Sqrt[3]/10, 1}}, {-1, 0}]
      ],
     MaxCellMeasure -> {1 -> 0.001}
     ],
    2
    ][[1]];
Area[poly]

0.523599

Graphics[{Circle[], Gray, EdgeForm[{Thick, Black}], poly}]

enter image description here

$\endgroup$
4
$\begingroup$
   Graphics[{Red, Opacity@0.7, Disk[{0, 0}, 10], Opacity@1, Blue, Thick, 
      Circle[{0, 0}, 10, {π/6, π/3}], 
      Circle[{0, 0}, 10, {-(π/6), -(π/3)}], Green, Opacity@0.6, 
      Rectangle[{10 Cos[π/3], -10 Sin[π/3]}, {10 Cos[π/6], 
        10 Sin[π/3]}]}, Axes -> True, AxesOrigin -> {0, 0}]

enter image description here

Therefore we can use the following.

reg1 = Disk[{0, 0}, 10];
reg2 = Rectangle[{10 Cos[π/3], -10 Sin[π/3]}, {10 Cos[π/ 6], 10 Sin[π/3]}];
reg=RegionIntersection[reg1, reg2];  
 Area@reg

$\frac{50 \pi }{3}$

Show[Graphics[{Circle[{0, 0}, 10]}, Axes -> True], 
 Region[reg, BaseStyle -> {LightBlue, EdgeForm[{Red, Thick}]}]]

enter image description here

You can also choose reg2 as

reg2 = Rectangle[{5, -5 Sqrt[3]}, {5 Sqrt[3], 5 Sqrt[3]}];

Or

reg2 = Rectangle[{5, -10}, {5 Sqrt[3], 10}];
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.