# Can Mathematica prove inequalities involving complex numbers?

I am given two complex numbers $$z$$ and $$w$$ that satisfy the following constraint $$|z - \overline{z}w| + |w|^2 < 1.$$

I want to see if the following inequality is true $$z^2 \overline{w} + \overline{z}^2w + |w|^2(z^2 \overline{w} + \overline{z}^2w - 4|z|^2) \geq 0.$$ Is it possible for Mathematica to prove or disprove the above inequality?

• Could you please provide code for those inequalities? – Andrew Dec 29 '18 at 19:32
• |z - conjugate[z]w| + |w|^2 < 1 – Jaikrishnan Dec 29 '18 at 19:39
• z^2 * conjugate[w] + conjugate[z]^2 * w + |w|^2 * (z^2 * conjugate[w] + conjugate[z]^2 * w - 4|z|^2) >= 0 – Jaikrishnan Dec 29 '18 at 19:47
• That's not what he was looking for – ktm Dec 30 '18 at 17:33
• People here generally like users to post code as Mathematica code instead of just images or TeX, so they can copy-paste it. It makes it convenient for them and more likely you will get someone to help you. You may find this this meta Q&A helpful – Michael E2 Jan 1 '19 at 16:28

z = x + I y;
w = u + I v;
ineq1 = Abs[z - Conjugate[z] w] + Abs[w]^2 < 1 // ComplexExpand;
ineq2 = z^2*Conjugate[w] + Conjugate[z]^2*w +
Abs[w]^2*(z^2*Conjugate[w] + Conjugate[z]^2*w - 4 Abs[z]^2) >= 0 //
ComplexExpand;


This gives a counterexample:

res = FindInstance[{ineq1, ! ineq2}, {x, y, u, v}, Reals]


$$\left\{\left\{x\to -\frac{11}{32},y\to \frac{29}{32},u\to -\frac{3}{4},v\to -\frac{7}{16}\right\}\right\}$$

Check:

{ineq1, ineq2} /. res


$$\left( \begin{array}{cc} \text{True} & \text{False} \\ \end{array} \right)$$

Resolve[
ForAll[{z, w},
Abs[z - Conjugate[z] w] + Abs[w]^2 < 1,
z^2 Conjugate[w] + Conjugate[z]^2 w +
Abs[w]^2 (z^2 Conjugate[w] + Conjugate[z]^2 w - 4 Abs[z]^2) >= 0
],
Complexes
]


False

• Or simply inequality /. {z -> I, w -> 1}. – Michael E2 Dec 29 '18 at 20:53
• @MichaelE2 It's always easier if you already have a counterexample ;) Nice catch though! The truth is i just love existential quantifiers ^_^ – Thies Heidecke Dec 29 '18 at 20:56
• My first try on complicated expressions is usually to plug in a bunch of Random*[] stuff and check, which is pretty easy in M. This inequality came out mostly false, so I tried something simple. Already upvoted cuz I like quantifiers too. :) – Michael E2 Dec 29 '18 at 21:00

With your inequality you should be careful about what you mean by "greater" or "less". Since the complex plane is principally vectors it is natural to compare magnitudes or 'radus' from the origin. Hence people normally use the absolute value.

You can naievely compare the real parts however this can result in absurd inequalities since moving along the complex axis retains the equality. 2 + i = 2 + 100 i

I'm afraid in the way you constructed your second inequality this is how Mathematica will handle the problem.

https://math.stackexchange.com/questions/1116022/can-a-complex-number-ever-be-considered-bigger-or-smaller-than-a-real-number