Project ParametricPlot3D onto 2D plane

Question

I have this ParametricPlot3D:

generated by this code:

x[α_, β_, γ_, t_] :=
  Sin[α] Cos[β] Cos[γ] Cos[t] + Sin[α] Sin[γ] Sin[t] - Cos[α] Sin[β] Cos[γ];
y[α_, β_, γ_, t_] := 
  Sin[α] Cos[β] Sin[γ] Cos[t] + Sin[α] Cos[γ] Sin[t] + Cos[α] Sin[β] Sin[γ];
z[α_, β_, t_] := 
 Sin[α] Sin[β] Cos[t] + Cos[α] Cos[β]

α = π/3;
β = +π/3;
γ = 0;

Show[
  ParametricPlot3D[{Cos[u] Sin[v], Cos[u] Cos[v], Sin[u]}, {u, 0, π}, {v, -π/2, π/2},
    Mesh -> None, 
    PlotStyle -> Opacity[.25, Blue], PlotPoints -> 80, 
    MaxRecursion -> 4, 
    ExclusionsStyle -> ({Directive[Opacity[1], Thick, Red]}), 
    Boxed -> False, Axes -> False], 
  ParametricPlot3D[Normalize[{x[α, β, γ, t], y[α, β, γ, t], z[α, β, t]}], {t, 0, π}], 
  ParametricPlot3D[Normalize[{-x[α, β, γ, -t], -y[α, β, γ, -t], z[α, β, -t]}], {t, 2 π, π}],
  Graphics3D[{PointSize[0.025], Point[{0, 0, 1}]}],
  ViewPoint -> Front]

--

I want to project it down to a 2D plane so that I see something like this:

Any ideas?

EDIT:

The result of

Plot[Normalize[{x[α, β, γ, t], y[α, β, γ, t], z[α, β, t]}][[ ;; 2]], {t, 0, 2 π}]

is

EDIT 2

Trying to set $z=0$ in the parameterisation:

Show[
  ParametricPlot3D[{Cos[u] Sin[v], Cos[u] Cos[v], Sin[u]}, {u, 0, π}, {v, -π/2, π/2},
    Mesh -> None, 
    PlotStyle -> Opacity[.25, Blue], PlotPoints -> 80, 
    MaxRecursion -> 4, 
    ExclusionsStyle -> ({Directive[Opacity[1], Thick, Red]}), 
    Boxed -> False, Axes -> False], 
  ParametricPlot3D[Normalize[{x[α, β, γ, t], y[α, β, γ, t], 0}], {t, 0, π}], 
  ParametricPlot3D[Normalize[{-x[α, β, γ, -t], -y[α, β, γ, -t], 0}], {t, 2 π, π}], 
  Graphics3D[{PointSize[0.025], Point[{0, 0, 1}]}],
  ViewPoint -> Front]

Answer 1

Note that due to the use of Normalize, you may get wrong results if you just substitute z with 0. Also, the 3D plot only shows part where $z>0$, so:

Show[
  ParametricPlot[{Cos[u], Sin[u]}, {u, 0, 2 π}], 
  ParametricPlot[Most@Normalize[{x[α, β, γ, t], y[α, β, γ, t], z[α, β, t]}],
    {t, 0, π}, 
    RegionFunction -> Function[{x, y, t}, z[α, β, t] > 0]],
  ParametricPlot[Most@Normalize[{-x[α, β, γ, -t], -y[α, β, γ, -t], z[α, β, -t]}],
    {t, π, 2 π}, 
    RegionFunction -> Function[{x, y, t}, z[α, β, -t] > 0]]
 ]

EDIT

To put this in a 3D plot, try this idea:

p1 = Flatten[{Most[Normalize[{x[\[Alpha], \[Beta], \[Gamma], t], y[\[Alpha], \[Beta], \[Gamma], t], z[\[Alpha], \[Beta], t]}]], 0}];
p2 = Flatten[{Most[Normalize[{-x[\[Alpha], \[Beta], \[Gamma], -t], -y[\[Alpha], \[Beta], \[Gamma], -t], z[\[Alpha], \[Beta], -t]}]], 0}];
Show[ParametricPlot3D[{Cos[u], Sin[u], 0}, {u, 0, 2 \[Pi]}, 
  Axes -> False, Boxed -> False], 
 ParametricPlot3D[p1, {t, 0, \[Pi]}, 
  RegionFunction -> 
   Function[{xc, yc, zc, t}, z[\[Alpha], \[Beta], t] > 0]],
 ParametricPlot3D[p2, {t, \[Pi], 2 \[Pi]}, 
  RegionFunction -> 
   Function[{xc, yc, zc, t}, z[\[Alpha], \[Beta], -t] > 0]],
 Graphics3D[{PointSize[0.025], Point[{0, 0, 0}]}]]

Answer 2

Try ViewPoint -> Top instead of ViewPoint -> Front in your plot:

Parallel projection: ViewVector -> {{0, 0, 1000}, {0, 0, -1}}: