Mathematica is not responding for very large numbers

Question

So, I am having Mathematica 11.3 and trying to evaluate 2^1,000,000,000.

When I am trying to show the output in its full form to manipulate the digits, Mathematica stops responding.

I am having 32GB of memory so this would not be a problem. Also when I am using Intel's extreme utility to monitor, I find it to always employ 1 kernel out of 8, altho I specifically set it to work with all 8 in the settings and never uses more than 6GB of memory.

Answer 1

The Mathematica kernel can handle such numbers. The following returns immediately; note that I suppressed the output with ;.

var = 2^1000000000;

The issue you are perhaps experiencing is that the front-end takes a long time to format and print the number. This is because it is an Integer

Head@var

Integer

and has a large amount of digits

IntegerLength@var

301029996

and Mathematica fully prints all digits of integers so this will take the front-end some time. You can return a portion of the digits with IntegerDigits; first 10 below.

IntegerDigits[var, 10, 10]

{1, 7, 8, 7, 1, 0, 9, 3, 7, 6}

You can get better print performance using reals instead of integers. The follow returns the print immediately.

var2 = 2.^1000000000

4.612976001169*10^301029995

RealDigits can be used to return digits in this case.

RealDigits[var2, 10, 10]

{{4, 6, 1, 2, 9, 7, 6, 0, 0, 1}, 301029996}

Hope this helps.

Answer 2

[Not a full answer but on the long side for comments.]

It is probably a formatting speed issue. Also note that obtaining the digits in base 10 also takes time (it's an O(n log n) algorithm for n the bit length of the number). One way to see that is as below. Notice that getting digits in base 2 is much faster (it's O(n)).

Table[{Timing[IntegerString[2^(10^n)];],
  Timing[IntegerString[2^(10^n), 2];]}, {n, 5, 8}]

(* Out[158]= {{{0., Null}, {0., Null}}, {{0.028, Null}, {0., 
   Null}}, {{0.396, Null}, {0.008, Null}}, {{6.924, Null}, {0.12, 
   Null}}} *)

I would expect that IntegerString might format faster than printing the digits directly, but I'm too scared to try on my memory-limited machine.

As for sizes: the number will occupy an eight of a gig, since it is exactly a billion bits.

ee = 2^(10^9);
ByteCount[ee]

(* Out[14]= 125000080 *)

In decimal form, at one byte per character, it will be around 300Mb. This is computed more accurately by any of the means below.

Log[10., 2]*10^9

(* Out[20]= 3.01029995664*10^8 *)

Timing[eeString = IntegerString[ee];]
ByteCount[eeString]
StringLength[eeString]

(* Out[21]= {106.264, Null}

Out[22]= 301030064

Out[23]= 301029996 *)