2
$\begingroup$

I'm trying to simplify this expression with Mathematica.

$\sqrt{2-a^2-2\sqrt{1-a^2}}, 0<a<1$

It can be simplified as

$\sqrt{1+1-a^2-2\sqrt{1-a^2}}=\sqrt{(1-\sqrt{1-a^2})^2}=1-\sqrt{1-a^2}$

denesting original radical. I used the command

FullSimplify[Sqrt[2 - a^2 - 2 Sqrt[1 - a^2]], 0 < a < 1]

but it doesn't work.

Any idea?

$\endgroup$
2
$\begingroup$

Try this:

Simplify[Sqrt[2 - a^2 - 2 Sqrt[1 - a^2]] /. a^2 -> 1 - x] /. 
 x -> 1 - a^2

(*  Sqrt[(-1 + Sqrt[1 - a^2])^2]   *)

Have fun!

$\endgroup$
  • 1
    $\begingroup$ Include assumption Simplify[Sqrt[2 - a^2 - 2 Sqrt[1 - a^2]] /. a^2 -> 1 - x, 0 < x < 1] /. x -> 1 - a^2 $\endgroup$ – Bob Hanlon Nov 27 '18 at 15:04
1
$\begingroup$
Reduce[Reduce[y == Sqrt[2 - a^2 - 2 Sqrt[1 - a^2]] && 0 < a < 1, a, Reals], y, Reals]

or

FullSimplify[Sqrt[2 - a^2 - 2 Sqrt[1 - a^2]], 
 TransformationFunctions -> {Reduce[Reduce[y == # && 0 < a < 1, a, Reals], y, Reals] &}]

0 < a < 1 && y == 1 - Sqrt[1 - a^2]

Sqrt[2-a^2-2 Sqrt[1-a^2]] /. Sqrt[a_ + b : k_. Sqrt[x_]]:>
  Sqrt[(a+Sqrt[a^2-b^2])/2]+Sign[k] Sqrt[(a-Sqrt[a^2-b^2])/2] // Simplify[#,0<a<1]&

1 - Sqrt[1 - a^2]

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.