Expansion of the Meijer G Function

Question

I'm trying to do the integral

Integrate[ B^2*BesselK[0, ko*ρ]^2*2 π*ρ, {ρ, a, ∞}]

which I figured should be relatively simple as the integral of a Bessel Function outside of a certain circle (of radius a) from a to infinity. Mathematica throws me the answer

ConditionalExpression[(B^2 π^(3/2) MeijerG[{{}, {3/2}}, {{0, 1, 1}, {}}, a^2 ko^2])/(2 ko^2), Re[a] > 0 && Im[a] == 0 && Re[ko] > 0]

The conditional expression is expected, but I was wondering if it's possible to expand the G function in terms of other Bessel Functions, especially the modified one $K_o$. Integrating across both regions and subtracting them gives a similar answer; while the answer for the integration from $0\to \inf$ is a constant, the integral from 0 to a involves the G function again, like

Integrate[B^2*BesselK[0, ko*ρ]^2*2 π*ρ, {ρ, 0, a}] 

ConditionalExpression[( B^2 π^(3/2) MeijerG[{{1}, {3/2}}, {{1, 1, 1},{0}},a^2 ko^2])/(2 ko^2), Re[a ko] > 0]

I'm hoping to get a wholly symbolic answer or at least an expansion of one, I was wondering if it's possible to have Mathematica get rid of the G function stuff in these results?

Answer 1

Based on the comment by theorist

$Assumptions = a > 0 && ko > 0 && B ∈ Reals

int = 2*Pi*B^2*Integrate[BesselK[0, ko*ρ]^2*ρ, ρ]
(*π B^2 ρ^2 (BesselK[0, ko ρ]^2 - BesselK[1, ko ρ]^2)*)

Check answer

D[int, ρ] // FullSimplify
(* 2 π B^2 ρ BesselK[0, ko ρ]^2*)

ok

intinf = Limit[int, ρ -> ∞]
(*0*)

inta = int /. ρ -> a
(*π a^2 B^2 (BesselK[0, a ko]^2 - BesselK[1, a ko]^2)*)

int0 = Limit[int, ρ -> 0]
(*-((π B^2)/ko^2)*)

int0a = inta - int0
(*π a^2 B^2 (BesselK[0, a ko]^2 - BesselK[1, a ko]^2) + (π B^2)/ko^2*)

intainf = intinf - inta
(*π (-a^2) B^2 (BesselK[0, a ko]^2 - BesselK[1, a ko]^2)*)

A quick spot check numerically with B = 1, ko = 1, a = 1 both the above solutions matche the MeijerG answers.

Answer 2

I do not know the answer, however I would like to share what I have observed.

Basically, what we are trying to do is simplifying the expression (1/x) MeijerG[{{}, {3/2}}, {{0, 1, 1}, {}}, x] (upto an overall factor) into some Bessel functions.

I do not now the generally true answer. However, I do know the approximate answer for very small $x$ values, such that the error percentage is less than 1% for approximately $x<10^{-3.2}$.

The key point is to analyze the Mellin transformation. This is suggested by the definition of MeijerG, so we check its MellinTransform:

In[294]:= MellinTransform[MeijerG[{{},{3/2}},{{0,1,1},{}},z]/z,z,x]

$\frac{\Gamma (x-1) \Gamma (x)^2}{\Gamma \left(x+\frac{1}{2}\right)}$

We will now try to match this by Mellin transform of Bessel functions. In general, we see that

In[296]:= MellinTransform[{BesselK[n,z^(1/2)]/z^k,BesselJ[n,z^(1/2)]/z^k},z,x]

$\left\{2^{2 (x-k)-1} \Gamma \left(-k-\frac{n}{2}+x\right) \Gamma \left(-k+\frac{n}{2}+x\right),\frac{2^{2 (x-k)} \Gamma \left(-k+\frac{n}{2}+x\right)}{\Gamma \left(k+\frac{n}{2}-x+1\right)}\right\}$

Now, by trial and error, the closest I managed to get was

MellinTransform[2/Sqrt[\[Pi]] BesselK[0, z^(1/2)]^2, z, x]

$\frac{\Gamma (x)^3}{\Gamma \left(x+\frac{1}{2}\right)}$

One can check that $\frac{2 K_0\left(\sqrt{z}\right){}^2}{\sqrt{\pi }}$ indeed matches MeijerG in small $z$ in leading order.

Even though it is far from being a nice approximation in general, it still works well for small x.