Using DeleteCases to match a string pattern

Question

I am trying to remove all of the elements from a list that contain the characters "err" in that order.

I expect the following code to return an empty list:

DeleteCases[{"Aerr"}, __ ~~ "err"]

However it fails to recognize the pattern and will return the full List. What am I missing in the documentation for patterns? Perhaps it is an issue with DeleteCases, as I can use StringMatchQ to identify that the patterns match.

StringMatchQ["Aerr", __ ~~ "err"]

Returns True.

Answer 1

First note the FullForm of your pattern:

__ ~~ "err" //FullForm

StringExpression[BlankSequence[],"err"]

The pattern is a StringExpression, so you must use a string function, e.g., StringMatchQ instead of DeleteCases, which is expecting a normal pattern. Here are some other possibilities:

list = {"Aerr"};

Select[list, Not @* StringMatchQ[__ ~~ "err"]]
Pick[list, StringMatchQ[list, __ ~~ "err"], False]

{}

{}

Answer 2

DeleteCases[{"Aerr"}, _?(StringMatchQ[ "*err"]) ]

{}

For versions prior to version 10:

DeleteCases[{"Aerr"}, _?(StringMatchQ[#, "*err"] &)]

{}