Finding series expansion of solution of algebraic equation

Question

I have the following algebraic equation:

F[x_, y_] := x^4 - 2*x^3*y + Subscript[c, 1] + y*Subscript[c, 2] + 
    y^2*(1/Subscript[t, 3]^2 - Subscript[t, 2]/Subscript[t, 3]^2) + 
    x^2*(1 + y^2 - Subscript[t, 2]^2/Subscript[t, 3]^2 + 
        (y*(-2 - Subscript[t, 2]))/Subscript[t, 3]
    ) + 
    x*(y*(-1 + Subscript[t, 2]^2/Subscript[t, 3]^2) + 
        (y^2*(2 + Subscript[t, 2]))/Subscript[t, 3]) - 
    y^3/Subscript[t, 3]

or:

$$F(\text{x$\_$},\text{y$\_$})\text{:=}x^4-2 x^3 y+c_1+y c_2+y^2 \left(\frac{1}{t_3^2}-\frac{t_2}{t_3^2}\right)+x^2 \left(1+y^2-\frac{t_2^2}{t_3^2}+\frac{y \left(-2-t_2\right)}{t_3}\right)+x \left(y \left(-1+\frac{t_2^2}{t_3^2}\right)+\frac{y^2 \left(2+t_2\right)}{t_3}\right)-\frac{y^3}{t_3}$$

where $c_1,c_2,t_3,t_2$ are all constants.

From this I can construct the following curve, $E(x,y)=F(x,t_3 x^2 + t_2 x -y)$, and I would like to find the $x(y)$ solutions, $E(x(y),y)=0$.

This part is easy, just solve the above equation for x. Since $E(x,y)$ is of degree 4 in $x$ you get 4 solutions for $x(y)$.

What I want to do is compute the asymptotic expansion of each of these solutions. I have tried

sol=Solve[E[x,y]==0,x]
Series[
    x/.sol[[i]],
    {y,Infinity,1},
    Assumptions->{y>0,Subscript[t,3]>0,Subscript[t,2]>0,Subscript[c,1]>0,Subscript[c,2]>0}
]

where $i$ denotes one of the four solutions of $E$, but for some reason the computation is taking an exceedingly long time.

I suspect that either I have made a mistake at some point, not noticed some deficiency in the solution, or I am not using the most efficient method, but I can't seem to identify anything I have done wrong.

Any help with this computation would be greatly appreciated.

Answer 1

It is helpful to do a series expansion around $\sqrt[4]{y}$ since Series is now extra careful when dealing with fractional powers. Also, rather than using Series around the solution, it is much faster to replace $y$ with $y + O(y^{-n})$. That is, work the series from the inside out instead of the outside in. The downside of this approach is that you don't know the order that will be produced.

Let's see how this works. Take the first solution and replace $y$ with $s^4$:

xsol = x /. First @ Solve[F[x, Subscript[t, 3] x^2 + Subscript[t, 2]x - y] == 0, x] /. y -> s^4;

Next, replace $s$ with $s + O(s^{-n})$:

Assuming[Subscript[c, 1] > 0 && Subscript[c, 2] > 0 && Subscript[t, 2] > 0 && Subscript[t, 3] > 0 && s>0,
    Table[
        s[n_] = Series[xsol /. s -> Series[s, {s, Infinity, n}], {s, Infinity, 4}] //Simplify,
        {n, 2, 14}
    ]
] //Column //TeXForm

$\begin{array}{l} -\frac{s^2}{\sqrt{t_3}}+O\left(\frac{1}{\frac{1}{s}}\right) \\ -\frac{s^2}{\sqrt{t_3}}+O\left(\frac{1}{\left(\frac{1}{s}\right)^{3/4}}\right) \\ -\frac{s^2}{\sqrt{t_3}}+O\left(\frac{1}{\sqrt{\frac{1}{s}}}\right) \\ -\frac{s^2}{\sqrt{t_3}}+O\left(\frac{1}{\sqrt[4]{\frac{1}{s}}}\right) \\ -\frac{s^2}{\sqrt{t_3}}+O\left(\left(\frac{1}{s}\right)^0\right) \\ -\frac{s^2}{\sqrt{t_3}}-\frac{t_2-1}{2 t_3}+O\left(\sqrt[4]{\frac{1}{s}}\right) \\ -\frac{s^2}{\sqrt{t_3}}-\frac{t_2-1}{2 t_3}+O\left(\sqrt{\frac{1}{s}}\right) \\ -\frac{s^2}{\sqrt{t_3}}-\frac{t_2-1}{2 t_3}+O\left(\left(\frac{1}{s}\right)^{3/4}\right) \\ -\frac{s^2}{\sqrt{t_3}}-\frac{t_2-1}{2 t_3}+O\left(\left(\frac{1}{s}\right)^1\right) \\ -\frac{s^2}{\sqrt{t_3}}-\frac{t_2-1}{2 t_3}-\frac{i}{2 s t_3^{5/4}}+O\left(\left(\frac{1}{s}\right)^2\right) \\ -\frac{s^2}{\sqrt{t_3}}-\frac{t_2-1}{2 t_3}-\frac{i}{2 s t_3^{5/4}}+\frac{-t_2^2+4 t_2-3}{8 s^2 t_3^{3/2}}+O\left(\left(\frac{1}{s}\right)^3\right) \\ -\frac{s^2}{\sqrt{t_3}}-\frac{t_2-1}{2 t_3}-\frac{i}{2 s t_3^{5/4}}+\frac{-t_2^2+4 t_2-3}{8 s^2 t_3^{3/2}}+\frac{i \left(t_2^2-4 t_2+3\right)}{16 s^3 t_3^{7/4}}+O\left(\left(\frac{1}{s}\right)^4\right) \\ -\frac{s^2}{\sqrt{t_3}}-\frac{t_2-1}{2 t_3}-\frac{i}{2 s t_3^{5/4}}+\frac{-t_2^2+4 t_2-3}{8 s^2 t_3^{3/2}}+\frac{i \left(t_2^2-4 t_2+3\right)}{16 s^3 t_3^{7/4}}+\frac{1}{4 s^4}+O\left(\left(\frac{1}{s}\right)^5\right) \\ \end{array}$

We see that in order to get a result good to order $O(s^{-5})$ we needed to replace $s$ with $s + O(s^{-15})$.

Finally, recall that $s$ is actually $\sqrt[4]{y}$. So, the final result is:

Series[Normal[s[14]] /. s->y^(1/4), {y, Infinity, 1}] //TeXForm

$-\frac{\sqrt{y}}{\sqrt{t_3}}-\frac{t_2-1}{2 t_3}-\frac{i \sqrt[4]{\frac{1}{y}}}{2 t_3^{5/4}}+\frac{\left(-t_2^2+4 t_2-3\right) \sqrt{\frac{1}{y}}}{8 t_3^{3/2}}+\frac{i \left(t_2^2-4 t_2+3\right) \left(\frac{1}{y}\right)^{3/4}}{16 t_3^{7/4}}+\frac{1}{4 y}+O\left(\left(\frac{1}{y}\right)^{5/4}\right)$

Answer 2

This will solve for x(y); I think I have not made any mistakes

Ftest[y_] := 
 x[y]^4 - 2 y*
   x[y]^3 - (1/Subscript[t, 3]) y^3 + ((1 - Subscript[t, 2])/
     Subscript[t, 3]^2) y^2 + (x[y]^2)*(y^2) - ((Subscript[t, 2] + 2)/
     Subscript[t, 3])*y*
   x[y]^2 + ((Subscript[t, 3]^2 - Subscript[t, 2]^2)/
     Subscript[t, 3]^2)*
   x[y]^2 + ((Subscript[t, 2] + 2)/Subscript[t, 3])*x[y]*
   y^2 + ((Subscript[t, 2]^2 - Subscript[t, 3]^2)/
     Subscript[t, 3]^2) x[y]*y + Subscript[c, 1]*x[y] + Subscript[c, 2]

Solve[Ftest[y] == 0, x[y]]

And then hopefully you will be able to get the Taylor series, by defining each solution as a function of y. Not the most automated method, but it should do the trick.

If you want to make the Taylor faster, then I suggest that you do some Factor and Simplify but not in the full thing. Rather take smaller bits, simplify them and then reconstruct the result out of the simplified versions.

Hopefully helpful.