How does CirclePoints function actually work when drawing a polygon?

Question

By reading that CirclePoints gives the positions of n points equally spaced around the unit circle, I understood that :

Graphics[{Green, Polygon[CirclePoints[4]]}] 

is equivalent to drawing a polygon into a circumscribed circle of radius 1 and centered as 0, 0.

I don't understand what CirclePoints with a real number does:

look at the picture:

Graphics[{Red, Polygon[CirclePoints[4.434335]], Green, 
  Polygon[CirclePoints[4]]}]

What is the meaning of placing "4.434335" points around the unit circle ?How do they come equally spaced ?

Look at the red polygon, they are not equally spaced, but I don't understand how the perimeter of the inner circle would be split.

Answer 1

The details section of the documentation says the following:

• In CirclePoints[n], n does not have to be an exact integer. The angles between successive vectors are always $\frac{2\pi}{n}$.
• If the angle $\theta_1$ is not given, it is assumed to be $\pi/n - \pi/2$, ...

($\theta_1$ is the starting angle.)

Here is a simple implementation to test this:

circlePoints[n_] := Module[{start, diff},
  start = Pi/n - Pi/2;
  diff = 2 Pi/n;
  Table[{Cos[start + i diff], Sin[start + i diff]}, {i, 0, Floor[n] - 1}]
  ]

Graphics[{
  Green,
  Polygon[CirclePoints[4.434335]],
  FaceForm[Transparent],
  EdgeForm[{Red, Thick}],
  Polygon[circlePoints[4.434335]]
  }]

How do they come equally spaced?

The key here is that successive vectors are equally spaced. The angle between the first and last vectors is not the same as the other angles unless $n$ is an integer.

Answer 2

here is how CirclePoints work

try this..

Graphics[{Point@CirclePoints[40.99]}]

the above misses a point
see this one

Graphics[{Point@CirclePoints[41]}]

now

Graphics[{Point@CirclePoints[4.43]}]   

misses the fifth point...
this one

Graphics[{Point@CirclePoints[5]}]