1
$\begingroup$

Considering two functions $\psi_{1}(u,v)$ and $\psi_{4}(u,v)$. we have these two parial differential equation for them

$(-2 i Sech[\frac{u}{\alpha}] \frac{\partial\psi_{4}}{\partial u}+2 i Sech[\frac{v}{\alpha}] \frac{\partial\psi_{4}}{\partial v})+(2 i Sech[\frac{u}{\alpha}] \frac{\partial\psi_{1}}{\partial u}+2 i Sech[\frac{v}{\alpha}] \frac{\partial\psi_{1}}{\partial v}-m\psi_{1})=0$

$(2 i Sech[\frac{u}{\alpha}] \frac{\partial\psi_{1}}{\partial u}-2 i Sech[\frac{v}{\alpha}] \frac{\partial\psi_{1}}{\partial v})+(-2 i Sech[\frac{u}{\alpha}] \frac{\partial\psi_{4}}{\partial u}-2 i Sech[\frac{v}{\alpha}] \frac{\partial\psi_{4}}{\partial v}-m\psi_{4})=0$

I need to find $\psi_{1}(u,v)$ and $\psi_{4}(u,v)$ I wrote these code for them but I don't know why is the problem and why it doesn't give the answer.

DSolve[{((-2 I Sech[u/α] D[ψ4[u, v], u]+2 ISech[v/α] D[ψ4[u, v], v]) + (-m ψ1 [u, v] + 2 I  Sech[u/α] D[ψ1[u, v], u] +2 I  Sech[v/α] D[ψ1[u, v], v])) ==0, ((2I Sech[u/α] D[ψ1[u, v], u]-2 I  Sech[v/α] D[ψ1[u, v], v]) + (-m ψ4[u, v] - 2 I  Sech[u/α] D[ψ4[u, v], u]-2 I  Sech[v/α] D[ψ4[u, v], v])) == 0}, {ψ1[u,v],ψ4[u, v]}, {u, v}]

I also tried NDSolve but still didn't get the answer

$\endgroup$
2
  • 2
    $\begingroup$ For a numerical solution, it is necessary to determine the initial and boundary conditions. $\endgroup$ Oct 13 '18 at 9:52
  • $\begingroup$ The code contains several errors. I corrected them in my answer. $\endgroup$ Oct 13 '18 at 13:14
1
$\begingroup$

This system of equations also can be solved symbolically, although not with DSolve. Beginning with

eq = {((-2 I Sech[u/α] D[ψ4[u, v], u] + 2 I Sech[v/α] D[ψ4[u, v], v]) + 
      (-m ψ1[u, v] + 2 I Sech[u/α] D[ψ1[u, v], u] + 2 I Sech[v/α] D[ψ1[u, v], v])), 
      (( 2 I Sech[u/α] D[ψ1[u, v], u] - 2 I Sech[v/α] D[ψ1[u, v], v]) + 
      (-m ψ4[u, v] - 2 I Sech[u/α] D[ψ4[u, v], u] - 2 I Sech[v/α] D[ψ4[u, v], v]))};

make the transformation,

rulet = {Sinh[u/α] -> ut, Sinh[v/α] -> vt};

with corresponding transformation of derivatives,

ruled = {Derivative[1, 0][ψ_][u, v] -> Derivative[1, 0][ψ][ut, vt] Cosh[u/α]/α, 
         Derivative[0, 1][ψ_][u, v] -> Derivative[0, 1][ψ][ut, vt] Cosh[v/α]/α, 
         ψ_[u, v] -> ψ[ut, vt]}

Applying this transformation then eliminates the independent variables from the coefficients of the equations.

Simplify[α eq /. ruled]
(* {((-2 I D[ψ4[ut, vt], ut] + 2 I D[ψ4[ut, vt], vt]) + 
      (-m α ψ1[ut, vt] + 2 I D[ψ1[ut, vt], ut] + 2 I D[ψ1[ut, vt], vt])), 
      (( 2 I D[ψ1[ut, vt], ut] - 2 I D[ψ1[ut, vt], vt]) + 
      (-m ψ4[ut, vt] - 2 I D[ψ4[ut, vt], ut] - 2 I D[ψ4[ut, vt], vt]))} *)

It follows, therefore, that the solution can be decomposed into Fourier modes,

{ψ1 -> Function[{ut, vt}, ψ10 Exp[I ku ut + I kv vt]], 
 ψ4 -> Function[{ut, vt}, ψ40 Exp[I ku ut + I kv vt]]}

or, in terms of the original variables,

{ψ1 -> Function[{u, v}, ψ10 Exp[I ku Sinh[u/α] + I kv Sinh[v/α]]], 
 ψ4 -> Function[{u, v}, ψ40 Exp[I ku Sinh[u/α] + I kv Sinh[v/α]]]}

The wavenumbers, {ku, kv} can be determined in the usual manner,

Simplify[eq Exp[-I ku Sinh[u/α] - I kv Sinh[v/α]]/.%];
CoefficientArrays[% I α/4, {ψ10, ψ40}] // Last // Normal // Det
(* ku kv - (m^2 α^2)/16 *)
$\endgroup$
2
  • $\begingroup$ Dear @bbgodfrey many thanks for your answer. I'm very glad that it has exact solution $\endgroup$
    – aber
    Oct 16 '18 at 3:15
  • $\begingroup$ I have a more general solution and shall post it later this week. $\endgroup$
    – bbgodfrey
    Oct 16 '18 at 3:46
2
$\begingroup$

An example of a numerical solution

eq = {((-2 I Sech[u/α] D[ψ4[u, v], u] + 2 I*Sech[v/α] D[ψ4[u, v], v]) 
        + (-m ψ1[u, v] + 2 I Sech[u/α] D[ψ1[u, v], u] 
        + 2 I Sech[v/α] D[ψ1[u, v], v])) == 0, ((2 I*Sech[u/α] D[ψ1[u, v], u] - 
        2 I Sech[v/α] D[ψ1[u, v], v]) + (-m ψ4[u, v] - 2 I Sech[u/α] D[ψ4[u, v], u] - 
        2 I Sech[v/α] D[ψ4[u, v], v])) == 0};

bc = {ψ1[0, v] == Exp[-v^2], ψ4[0, v] == 0, ψ1[L, v] == Exp[-L^2], ψ4[L, v] == 0};
L = 5; α = 1; m = 1;
s = NDSolve[{eq, bc}, {ψ1[u, v], ψ4[u, v]}, {u, 0, L}, {v, 0, L}];

Plot3D[Evaluate[Abs[ψ1[u, v]] /. s], {u, 0, L}, {v, 0, L}, 
 PlotRange -> All, PlotPoints -> 50, Mesh -> None, ColorFunction -> Hue]

fig1

$\endgroup$
2
  • $\begingroup$ Dear Alex Thank you very much. You helped a lot $\endgroup$
    – aber
    Oct 13 '18 at 15:18
  • $\begingroup$ @aber You're welcome! $\endgroup$ Oct 13 '18 at 17:00

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.