Printing a notebook without background color to save ink

Question

I sometimes need to print hard copies of my notebooks, but I really like having a background color to make the notebooks easier on my eyes. Is it possible to automatically remove the background color before sending to a printer? I couldn't find it on the options inspector. Thanks!

Answer 1

Printing uses the "Printout" screen environment. So, you can control this behavior automatically with a stylesheet. Something like:

SetOptions[
    EvaluationNotebook[],
    StyleDefinitions -> Notebook[
        {
        Cell[StyleData[StyleDefinitions->"Default.nb"]],
        Cell @ CellGroupData[
            {
            Cell[StyleData["Notebook"],Background->RGBColor[0.9, 1, 1]],
            Cell[StyleData["Notebook","Printout"],Background->None]
            },
            Open
        ]
        },
        StyleDefinitions->"PrivateStylesheetFormatting.nb"
    ]
]

ought to do it. Change the background as appropriate.

Check by toggling the ScreenEnvironment setting in the Format menu.

Addendum

If you want to make this change "permanent":

NotebookSave[
    Notebook[
        {
        Cell[StyleData[StyleDefinitions->"Default.nb"]],
        Cell @ CellGroupData[
            {
            Cell[StyleData["Notebook"],Background->RGBColor[0.9, 1, 1]],
            Cell[StyleData["Notebook","Printout"],Background->None]
            },
            Open
        ]
        },
        StyleDefinitions->"PrivateStylesheetFormatting.nb"
    ],
    FileNameJoin[
        {$UserBaseDirectory,"SystemFiles","FrontEnd","StyleSheets","Default.nb"}
    ]
]

and then the next time you open Mathematica you should see a blue screen. Just delete the file to return to the default behavior.