5
$\begingroup$

In the paper, entitled:

A Closed Form Solution for the Pull-in Voltage of the Micro Bridge

(Link to PDF: https://pdfs.semanticscholar.org/0d31/33707b1243f6b4e3344c4fa19b831b010b8b.pdf)

... the following equation appears:

enter image description here

I really don't know how to solve this for $\eta_{PI}$, even if all constants are known... do you have any idea ?

EDIT: Mathematica Input: ($n_{PI}$ was replaced with a simple $n$)

The nominator:

nom = Integrate[
  b*\[Phi][x]/(g - n*\[Phi][x])^2 + 
   0.265*b^0.25*\[Phi][x]/(g - n*\[Phi][x])^1.25 + 
   0.53*h^0.5*\[Phi][x]/(g - n*\[Phi][x])^1.5, {x, 0, L}]

The denominator:

denom = Integrate[
  2*b*(\[Phi][x])^2/(g - n*\[Phi][x])^3 + 
   0.33125*b^0.25*(\[Phi][x])^2/(g - n*\[Phi][x])^2.25 + 
   0.795*h^0.5*(\[Phi][x])^2/(g - n*\[Phi][x])^2.5, {x, 0, L}]

A typical $ \phi (x)$ function:

\[Phi][x] := a*Sin[x] + b*Cos[x] + c*Sinh[x] + d*Cosh[x]

Some arbitrary constants for numeric solutions to test:

constants = {a->2,b->4,c->7,d->10,g->3,h->2,L->5}

For easier copy-paste:

Clear[\[Phi]]
nom = Integrate[
  b*\[Phi][x]/(g - n*\[Phi][x])^2 + 
   0.265*b^0.25*\[Phi][x]/(g - n*\[Phi][x])^1.25 + 
   0.53*h^0.5*\[Phi][x]/(g - n*\[Phi][x])^1.5, {x, 0, L}]

denom = Integrate[
  2*b*(\[Phi][x])^2/(g - n*\[Phi][x])^3 + 
   0.33125*b^0.25*(\[Phi][x])^2/(g - n*\[Phi][x])^2.25 + 
   0.795*h^0.5*(\[Phi][x])^2/(g - n*\[Phi][x])^2.5, {x, 0, L}]
$\endgroup$
  • 3
    $\begingroup$ The first thing you could do is to translate the image into Mathematica code. Otherwise, chances are nobody will bother to do it for you, and you won't get any answers. $\endgroup$ – AccidentalFourierTransform Oct 6 '18 at 19:47
  • 1
    $\begingroup$ Presumably, some of the terms in the integrand have an implicit dependence on x. You will have to work out what this is and make it explicit. $\endgroup$ – mikado Oct 6 '18 at 20:02
  • $\begingroup$ @AccidentalFourierTransform Thank you for your comment. Please have a look at my update. $\endgroup$ – james Oct 7 '18 at 6:44
  • 1
    $\begingroup$ From paper ϕ[x] is :ϕ[x] == (Cosh[λ x] - Cos[λ x]) - (Cosh[λ L] - Cos[λ L])/(Sinh[λ L] - Sin[λ L])*(Sinh[λ x] - Sin[λ x]) then: λ is ? or from eq (3) ?. Solving eq(3) for λ then: λ =0 ,and then ϕ[x]=0 ? $\endgroup$ – Mariusz Iwaniuk Oct 7 '18 at 9:57
  • 3
    $\begingroup$ I am mildly amused at the loose use of "closed form" in the paper. $\endgroup$ – J. M. will be back soon Oct 7 '18 at 10:59
5
$\begingroup$
b = 50*10^-6;
g = 3*10^-6;
h = 2*10^-6;
L = 250*10^-6;
λ = 10; (* λ = ? .You may change. *)

ϕ[x_?NumericQ] := (Cosh[λ x] - Cos[λ x]) - (Cosh[λ L] - Cos[λ L])/(Sinh[λ L] - Sin[λ L])*(Sinh[λ x] - Sin[λ x])

nom[n_?NumericQ] := NIntegrate[(b ϕ[x])/(g - n ϕ[x])^2 + 53/100*( h^(1/2) ϕ[x])/(g - n ϕ[x])^(3/2) + 
53/200*( b^(1/4) ϕ[x])/(g - n ϕ[x])^(5/4), {x, 0, L}, Method -> "LocalAdaptive"]

denom[n_?NumericQ] := NIntegrate[(2 b ϕ[x]^2)/(g - n ϕ[x])^3 + 159/200*( h^(1/2) ϕ[x]^2)/(g - n ϕ[x])^(5/2) + 
53/160*( b^(1/4) ϕ[x]^2)/(g - n ϕ[x])^(9/4), {x, 0, L}, Method -> "LocalAdaptive"]

Solve for n:

FindRoot[n - nom[n]/denom[n] == 0, {n, 2}, WorkingPrecision -> 20, MaxIterations -> 1000]

(* {n -> 1.2897501610140538697} *)
$\endgroup$
  • $\begingroup$ Wow ! This is great! Thank you so much !! What doe x_?Numeric do and why do you use it ? $\endgroup$ – james Oct 7 '18 at 11:16
  • $\begingroup$ @james .It's defintion of a function that only evaluates when its argument is numeric. More in Documentation, exectute: ?NumericQ. $\endgroup$ – Mariusz Iwaniuk Oct 7 '18 at 11:31
  • 2
    $\begingroup$ @james Here's a site reference for NumericQ: mathematica.stackexchange.com/questions/18393/… $\endgroup$ – Michael E2 Oct 7 '18 at 12:05
  • $\begingroup$ @MichaelE2 Thanks for the link to the documentation. $\endgroup$ – james Oct 7 '18 at 17:38
  • $\begingroup$ @MariuszIwaniuk Thank you for the explanation ! $\endgroup$ – james Oct 7 '18 at 17:38

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.