Convert List of Equations To Coefficient Matrix

Question

I have the following list of 2 equations (but generally I have much more than 2 equations):

  m= {A1*x+B1*Sin[x]-C1*Cos[x],C2+A2*Cosh[x]}

How could I automatically convert it into a coefficient matrix, like that:

$$\left( \begin{array}{cccccc} \text{A1} \text{x4} & \text{B1} \sin (\text{x4}) & \text{-C1} \cos (\text{x4}) & 0 & 0 & 0 \\ 0 & 0 & 0 & \text{A2} \cosh (\text{x4}) & \text{0} & \text{C2} \\ \end{array} \right)$$

Each row of the coefficient matrix corresponds to an element of the m list and is sorted from A to Z.

Some more details:

Basically I have two equations:

(1) A1*x+B1*Sin[x]-C1*Cos[x]

(2) C2+ A2*Cosh[x]

Those equations are listed in the m list. I could rewrite those equations like that:

(1) A1*x + B1*Sin[x] - C1*Cos[x] + 0*A2 + 0*B2+0*C2

(2) 0*A1 + 0*B1 + 0*C1+A2*Cosh[x] + 0*B2+C2

Now I create the coefficient matrix:

$$\left( \begin{array}{cccccc} \text{A1} \text{x4} & \text{B1} \sin (\text{x4}) & \text{-C1} \cos (\text{x4}) & 0 & 0 & 0 \\ 0 & 0 & 0 & \text{A2} \cosh (\text{x4}) & \text{0} & \text{C2} \\ \end{array} \right)$$

Answer 1

 vars = {A1, B1, C1, A2, B2, C2};
 vars # & /@ CoefficientArrays[m, vars][[2]] // MatrixForm // TeXForm 

$\left( \begin{array}{cccccc} \text{A1} x & \text{B1} \sin (x) & -\text{C1} \cos (x) & 0 & 0 & 0 \\ 0 & 0 & 0 & \text{A2} \cosh (x) & 0 & \text{C2} \\ \end{array} \right)$

Update: to also automate vars:

ClearAll[f]
f[n_, m_] := Flatten@Transpose[Outer[Symbol@StringJoin[##] &, 
  CharacterRange["A", "Z"][[;; m]], ToString /@ Range[n]]]

Examples:

f[2, 3]

{A1, B1, C1, A2, B2, C2}

f[4, 4]

{A1, B1, C1, D1, A2, B2, C2, D2, A3, B3, C3, D3, A4, B4, C4, D4}

Answer 2

CoefficientArrays is quite suitable for this job.

m = {A1 x + B1 Sin[x] - C1 Cos[x], C2 + A2 Cosh[x]};
eqs = Thread[m + {a, b} == 0];
CoefficientArrays[eqs, {A1, B1, C1, A2, B2, C2}] // Normal

{{a, b}, 
 {{x, Sin[x], -Cos[x], 0, 0, 0},
  {0, 0, 0, Cosh[x], 0, 1}}
}