0
$\begingroup$

i have a system of equations in which there are two parameters F, G. I choose F,G positive. the code is:

G > 0
F > 0

Reduce[{(1/Sqrt[V (Z *H*P - V*MU)]) == (F*G)^(-1/2), 
  Sqrt[(Z *H*P - V*MU)/V] Z^-1 == (F/G)^(1/2), 
  Sqrt[(Z *H*P - V*MU)/V] H^-1 == (G/F)^(1/2), 
  Sqrt[(Z *H*P - V*MU)/V] P^-1 == (F*G)^(
   1/2), ((Z *H*P - V*MU)^(3/2)/(V^(3/2)*Z *H*P) ) == (F*G)^(1/2), 
  MU == 0}, {V, Z , H, P, MU}, Reals]

But i obtain this:

((G < 0 && F < 0 && V == 1 && Z == -G && H == (F G)/Z && 
     P == (H Z)/(F G)) || (G > 0 && F > 0 && V == 1 && Z == G && 
     H == (F G)/Z && P == (H Z)/(F G))) && MU == 0

Why? I choose F,G positive and why it considers all the possibility? Another thing is it finds the value , for example, of Z but it doesn't substitute it into the result of H and P.

Thank you

$\endgroup$
0
$\begingroup$

Inequalities standing by themselves have no effect on anything. They must be used as Assumptions (directly or through $Assumptions) in functions that take the option Assumptions. Reduce does not use Assumptions so the inequalities must be included in the system of equations and constraints given as its first argument. Also, using the option Backsubstitution will give cleaner results.

Reduce[{(1/Sqrt[V (Z*H*P - V*MU)]) == (F*G)^(-1/2), 
  Sqrt[(Z*H*P - V*MU)/V] Z^-1 == (F/G)^(1/2), 
  Sqrt[(Z*H*P - V*MU)/V] H^-1 == (G/F)^(1/2), 
  Sqrt[(Z*H*P - V*MU)/V] P^-1 == (F*G)^(1/
      2), ((Z*H*P - V*MU)^(3/2)/(V^(3/2)*Z*H*P)) == (F*G)^(1/2), MU == 0 , 
  G > 0, F > 0}, {V, Z, H, P, MU}, Reals, Backsubstitution -> True]

(* G > 0 && F > 0 && V == 1 && Z == G && H == F && P == 1 && MU == 0 *)

Note that the constraints are included in the result. If you wish them removed, use Simplify with the constraints as Assumptions.

Simplify[%, {G > 0, F > 0}]

(* V == 1 && G == Z && F == H && P == 1 && MU == 0 *)

You could also use Solve rather than Reduce.

Solve[{(1/Sqrt[V (Z*H*P - V*MU)]) == (F*G)^(-1/2), 
   Sqrt[(Z*H*P - V*MU)/V] Z^-1 == (F/G)^(1/2), 
   Sqrt[(Z*H*P - V*MU)/V] H^-1 == (G/F)^(1/2), 
   Sqrt[(Z*H*P - V*MU)/V] P^-1 == (F*G)^(1/
       2), ((Z*H*P - V*MU)^(3/2)/(V^(3/2)*Z*H*P)) == (F*G)^(1/2), MU == 0 , 
   G > 0, F > 0}, {V, Z, H, P, MU}, Reals] // Simplify[#, {G > 0, F > 0}] &

(* {{V -> 1, Z -> G, H -> F, P -> 1, MU -> 0}} *)
$\endgroup$
  • $\begingroup$ thank you for the informations. i'm new on mathematica $\endgroup$ – Mordin Solus Oct 3 '18 at 16:37

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.