make a slider for a list of matrices

Question

I have a list of matrices, called $matList$, which are sequentially multiplied by another matrix $G$. I created a slider for $matList$, but the slider does not work. Here is the Code.

Clear[a, t, matList, G, solG, solGTr, mat];
Manipulate[
 SeedRandom[2];
 a = RandomReal[{0, 1}, {3, 5}];
 t = RandomReal[{0, 1}, {3, 5}];
 matList = 
  Table[(# - DiagonalMatrix[Diagonal[#]]) &[
    KroneckerProduct[a[[i]], t[[i]]]], {i, 1, 3}]; 
 G = {{0, 1, 0, 0, 1}, {1, 0, 0, 1, 1}, {1, 0, 0, 1, 0}, {0, 1, 1, 0, 
    0}, {1, 0, 0, 1, 0}};
 solG = G*mat;
 solGTr = Transpose[solG];
 Grid[{   
   {Text["matrix solG"], Text["transpose of solG"]}, {solG, solGTr}   
       }],
 Row[{Control[{mat, matList, Animator, AnimationRunning -> False}]}]
 ]

The problem in the above Code lies in Row[{control[{mat,matList,...}]. A similar construct for a slider of a list of numbers works, though.

Answer 1

More an extended comment than an answer.

In addition to what kglr has said, you might have much more fun with this if you move the random matrix generation and the preliminary calculations out of the Manipulate environment:

Clear[a, t, matList, G, solG, solGTr, mat];
SeedRandom[2];
n = 30;
a = RandomReal[{0, 1}, {n, 5}];
t = RandomReal[{0, 1}, {n, 5}];
matList = 
  Table[(# - DiagonalMatrix[Diagonal[#]]) &[KroneckerProduct[a[[i]], t[[i]]]], 
   {i, 1, n}];
G = {{0, 1, 0, 0, 1}, {1, 0, 0, 1, 1}, {1, 0, 0, 1, 0}, {0, 1, 1, 0,0}, {1, 0, 0, 1, 0}};
Manipulate[
 solG = G*matList[[k]];
 solGTr = Transpose[solG];
 Grid[{{Text["matrix solG"], Text["transpose of solG"]}, {solG,solGTr}}], 
 {{k, 1}, 1, Length@matList, 1, Animator, AnimationRunning -> False}
 ]

Answer 2

Maybe if you want a slider, use Slider:

SeedRandom[2];
a = RandomReal[{0, 1}, {3, 5}];
t = RandomReal[{0, 1}, {3, 5}];
matList = 
  Table[(# - DiagonalMatrix[Diagonal[#]]) &[
    KroneckerProduct[a[[i]], t[[i]]]], {i, 1, 3}];
G = {{0, 1, 0, 0, 1}, {1, 0, 0, 1, 1}, {1, 0, 0, 1, 0}, {0, 1, 1, 0, 
    0}, {1, 0, 0, 1, 0}};
Manipulate[
 With[{solG = G*mat}, {solGTr = Transpose[solG]},
  Grid[{{Text["matrix solG"], Text["transpose of solG"]},
    MatrixForm /@ {solG, solGTr}}]
  ],
 {mat, matList, Slider}]

---

If you don't have V10.4 or later or don't mind nested With, you can use the following variant:

Manipulate[
 With[{solG = G*mat}, With[{solGTr = Transpose[solG]},
   Grid[{{Text["matrix solG"], Text["transpose of solG"]},
     MatrixForm /@ {solG, solGTr}}]
  ]],
 {mat, matList, Slider}]

The important thing about With in both variants is that it avoids an extra update by Manipulate that occurs if the global variables solG and solGTr are given new values as they are in the OP. (When these updates are expensive, it can become a critical issue. In the example demo, updating is fast and the waste of time doesn't matter that much.)