Repeated replacing elements in the list

Question

I have a large list of the following form

{{1, 2} -> -1, {1, 1} -> 1, {1, 2} -> -1, {1, 6} -> 1}

and I want to combine all of the pairs x->y that share the same x value by adding up their y values. For the above example I want to have

{{1, 2} -> -2, {1, 1} -> 1, {1, 6} -> 1}

and I want to do it using patterns and ReplaceRepeated command. I tried the following code:

{{1, 2} -> -1, {1, 1} -> 1, {1, 2} -> -1, {1, 6} -> 1} //. 
  HoldPattern[{x_ -> y_, a___, x_ -> z_}] -> {x -> y + z, a}

Can anybody tell me why above code is not working and how can I do it using rules?

Answer 1

In general, there may (or may not) be preceding, intervening, and subsequent elements in the list that must handled using BlankNullSequence

{{1, 2} -> -1, {1, 1} -> 1, {1, 2} -> -1, {1, 6} -> 1} //. {start___, 
   x_ -> y1_, middle___, x_ -> y2_, end___} :> {start, x -> y1 + y2, middle, end}

(* {{1, 2} -> -2, {1, 1} -> 1, {1, 6} -> 1} *)

Answer 2

You could use GroupBy:

Normal @ GroupBy[
    {{1,2}->-1,{1,1}->1,{1,2}->-1,{1,6}->1},
    First -> Last,
    Total
]

{{1, 2} -> -2, {1, 1} -> 1, {1, 6} -> 1}

Answer 3

You can use SparseArray setting the system sub-option "TreatRepeatedEntries" to Plus:

SetSystemOptions["SparseArrayOptions" -> {"TreatRepeatedEntries" -> Plus}];
sa = SparseArray[{{1, 2} -> -1, {1, 1} -> 1, {1, 2} -> -1, {1, 6} -> 1}];
SetSystemOptions["SparseArrayOptions" -> {"TreatRepeatedEntries" -> First}];

Thread[sa@"NonzeroPositions" -> sa@ "NonzeroValues"]

{{1, 2} -> -2, {1, 1} -> 1, {1, 6} -> 1}