1
$\begingroup$

I need to obtain this using package FeynCalc: $$ \begin{align} [\gamma_{0},\gamma_{i}]=& 2 \gamma_{0}\gamma_{i}, \\ [\gamma_{i},\gamma_{0}]=& 2 \gamma_{i}\gamma_{0} , \\ [\gamma_{0},\gamma_{0}]=& 0, \\ \gamma_{0}.\gamma_{i}.\gamma_{0}.\gamma_{i} =& 1 , \\ \gamma_{0}.\gamma_{i}.\gamma_{i}.\gamma_{0} =& -1. \end{align}$$.

My gamma matrices are:

$\gamma_{0}= \lbrace \lbrace 0, \ \ \mathbb{I}_{2\times 2} \rbrace,\lbrace \mathbb{I}_{2\times 2}, \ \ 0 \rbrace \rbrace $

$\gamma_{i}= \lbrace \lbrace 0, \ \ -\sigma^{i} \rbrace,\lbrace \sigma^{i}, \ \ 0 \rbrace \rbrace $

and

$\sigma_{1}=\lbrace \lbrace 0, \ \ 1 \rbrace,\lbrace 1, \ \ 0 \rbrace \rbrace $

$\sigma_{2}=\lbrace \lbrace 0, \ \ -\mathrm i \rbrace,\lbrace \mathrm i, \ \ 0 \rbrace \rbrace $

$\sigma_{3}=\lbrace \lbrace 1, \ \ 0 \rbrace,\lbrace 0, \ \ -1 \rbrace \rbrace $

I'm working in D-4 space.

$\endgroup$
2
  • $\begingroup$ Please give show us what you have already tried. What is the definition of [] brackets and $.$? Commutators and matrix product? $\endgroup$
    – Johu
    Sep 29, 2018 at 20:45
  • $\begingroup$ [,] is my commutator, "." Is just multiplication sign. Sorry for that $\endgroup$
    – Kamog
    Sep 29, 2018 at 21:18

1 Answer 1

3
$\begingroup$

If you just want to verify some identities of Dirac gamma matrices in some certain representations. FeynCalc is not a necessity. Actually your choice of Dirac matrices is just the Weyl (chiral) representation:

$$ \gamma^\mu = \left( \begin{array}{ll} 0 & \sigma^\mu \\ \overline{\sigma}^\mu & 0 \end{array}\right), $$

which specifically are

$$ \begin{align} \gamma^0 &= \ \tau_1\otimes\sigma^0, \\ \gamma^i &= \mathrm i \tau_2\otimes\sigma^i. \end{align} $$

So according to the above equations, we can define the Dirac gamma matrices ourselves in the Wolfram language:

Clear[γ]
SetAttributes[γ, Listable]
γ[μ_] := If[μ == 0, KroneckerProduct @@ PauliMatrix[{1, μ}], 
                  I KroneckerProduct @@ PauliMatrix[{2, μ}]
           ]

Then that codes below return True means your first three identities are verified:

With[{commutator = #.#2 - #2.# &, γList = γ@Range[0, 3]},
     2 TensorProduct[DiagonalMatrix[{1, -1, -1, -1}], γ[0].γ[0]] + Outer[commutator, γList, γList, 1] == 
     2 Outer[Dot, γList, γList, 1]
    ]
True

As for the last two, it is easy to see:

Table[Dot @@ γ[{0, i, 0, i}], {i, 3}] == -Table[Dot @@ γ[{0, i, i, 0}], {i, 3}] == ConstantArray[IdentityMatrix[4], 3]
True

Bonus

To verify what speaks of the Clifford algebra, also the defining features of Dirac gamma matrices

$$ \{\gamma^\mu, \gamma^\nu\} = 2\eta^{\mu\nu}I_4, $$

one can compare the outcomes of the two pieces of codes:

With[{anticommutator = #.#2 + #2.# &, γList = γ[Range[0, 3]]},
     Outer[anticommutator, γList, γList, 1] // MatrixForm
    ]

2 DiagonalMatrix[{1, -1, -1, -1}]~TensorProduct~IdentityMatrix[4] // MatrixForm
$\endgroup$
2
  • $\begingroup$ Thank you sou much. What I need is a spin-connection, like I wrote in this topic: Defining commutations rules over arbitrary matrix $\endgroup$
    – Kamog
    Sep 30, 2018 at 12:43
  • 1
    $\begingroup$ using DiracSimplify my work is almost done, now I need just impose $\gamma_{0}\gamma_{i}\gamma_{0}\gamma_{i}=1$, $ \gamma_{0}.\gamma_{i}.\gamma_{i}.\gamma_{0} = -1$, $\gamma_{0}\gamma_{i}\gamma_{i}\gamma_{j}=0$ With FeynCalc package, is it possible? $\endgroup$
    – Kamog
    Oct 1, 2018 at 0:48

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.