List rearrangment with joining of strings

Question

I have a list of strings:

lis = {{"a","b","x"},{"d","e","y"},{"a","b","z"},{"d","c","x"},{"a","b","w"}}

I would like to use StringJoin on the last elements where initial elements are the same to obtain:

res = {{"a","b","xzw"},{"d","e","y"},{"d","c","x"}}

Doing:

lis = SortBy[lis, {#[[1]]} &]
SequenceCases[lis, {{a_, b_, c_}, {a_, b_, d_}} :> {a, b, StringJoin[c, d]}]

only gives:

{{"a", "b", "wx"}}

Thanks for any suggestions.

At least closely related: mathematica.stackexchange.com/q/26574/5478 — Kuba♦, Sep 27 '18 at 19:04
@Suite401, do you have control on how the "initials" are generated? If they where integers (which can be achieved with ToCharacterCode), then I could also image faster methods. — Henrik Schumacher, Sep 27 '18 at 19:43
@Henrik, Each actual element of the list looks like: {DateObject,String,String representation of integer,String,String representation of integer,String,String,String} so I'm not sure there's much to be done, but am interested in your thoughts. — Suite401, Sep 27 '18 at 19:53
Okay, my idea would have required that the number of keys is known a priorily. Btw., I found out that Carl Woll's code is much faster than mine. — Henrik Schumacher, Sep 27 '18 at 19:58

Carl Woll · Accepted Answer · 2018-09-27 19:43:21Z

7

Another variation:

KeyValueMap[Append] @ GroupBy[lis, Most->Last, StringJoin]

{{"a", "b", "xzw"}, {"d", "e", "y"}, {"d", "c", "x"}}

although you may like just the output of GroupBy[lis, Most->Last, StringJoin] better.

answered Sep 27 '18 at 19:43

Carl Woll

103k4 gold badges149 silver badges259 bronze badges

add a comment |

Henrik Schumacher · Accepted Answer · 2018-09-27 18:58:50Z

3

KeyValueMap[
 {key, value} \[Function] Join[key, {StringJoin[value]}],
 GroupBy[lis, Part[#, 1 ;; 2] & -> Last]
 ]

{{"a", "b", "xzw"}, {"d", "e", "y"}, {"d", "c", "x"}}

answered Sep 27 '18 at 18:58

Henrik Schumacher

77.4k6 gold badges118 silver badges217 bronze badges

$\begingroup$ That's probably the first time I've seen anyone use the infix function notation here. I forgot that even existed. $\endgroup$ – Sjoerd Smit Sep 27 '18 at 20:18
$\begingroup$ @Sjoerd Actually, I use it quite often... $\endgroup$ – Henrik Schumacher Sep 27 '18 at 20:19

add a comment |

Kuba · Accepted Answer · 2018-09-27 19:03:07Z

3

Another one:

 KeyValueMap[Append] @ Merge[StringJoin][ {#, #2} -> #3 & @@@ lis ]

answered Sep 27 '18 at 19:03

Kuba♦

125k12 gold badges231 silver badges599 bronze badges

$\begingroup$ Thanks Henrik, Kuba; am checking to see which is faster on big data set $\endgroup$ – Suite401 Sep 27 '18 at 19:06

add a comment |

3 Answers 3