Why does Assuming for Integrate not work as expected?

Question

I'm trying to perform the following integral with Mathematica 7:

Assuming[{t>0},
  Integrate[(-s^2 + 4*s*t + 2*alpha*s)^(-(1/2)*D),{s, 0, t}, {alpha, 0, Infinity}]]

If I perform the integration with just the t>0 assumption, Mathematica gives:

(1/(-2 + D))If[Re[D] < 2,
  ( 2^-D t^(2 - D) (
  -8 (-4 + D) Gamma[1 + D/2] Hypergeometric2F1[1 - D/2, D/2, 2 - D/2, 1/4]
  + (-2 + D) D Gamma[D/2] Hypergeometric2F1[2 - D/2, D/2, 3 - D/2, 1/4]
  ))/((-4 + D) (-2 + D) Gamma[1 + D/2]),
  Integrate[(-s (s - 4 t))^(1 - D/2)/s, {s, 0, t}, Assumptions -> Re[D] >= 2 && t > 0]]

which indicates that D must be less than 2. If I now use the additional assumption D<2 with Assuming[{t>0,D<2}, Mathematica says that the integral no longer converges. (Also with exchanged places for the integration variables, the integral can no longer be calculated).

Can anyone solve the mystery?

Thanks, Tobias

Answer 1

It really diverges.

I'll start with integrating over s. You actually integrate over alpha, so if this is a case where Fubini's theorem does not hold then this analysis might be wrong.

Integrate[(-s^2 + 4*s*t + 2*alpha*s)^(-(1/2)*d), {s, 0, t}, 
  Assumptions -> {t > 0, alpha > 0}]

(* ConditionalExpression[(2 alpha + 4 t)^(1 - d)
   Beta[t/(2 alpha + 4 t), 1 - d/2, 1 - d/2], Re[d] < 2] *)

This shows (as you knew) that we require d<2. So let's see where that takes us.

i1 = Integrate[(-s^2 + 4*s*t + 2*alpha*s)^(-(1/2)*d), {s, 0, t}, 
   Assumptions -> {t > 0, d < 2, alpha > 0}];

We can check behavior at the endpoints to assess convergence.

sinf = 
 Normal[Series[i1, {alpha, Infinity, 2}, 
   Assumptions -> {t > 0, d < 2, alpha > 0}]]

(* Out[102]= (alpha/t)^(d/2) (alpha + 2 t)^(
 1 - d) (-((2^(1 - d/2) t)/(alpha (-2 + d))) - (
   2^(-1 - d/2) (-16 + 5 d) t^2)/(alpha^2 (-4 + d))) *)

If you look closely you will see that the lead term in alpha is of magnitude alpha^(d/2)*alpha^(1-d)*alpha^(-1). This comes to alpha^(-d). Since d<2 this means we won't have convergence at infinity.