Problem with particular simplification of complex function under assumptions

Question

I have proven that $expr=(1 - i)(\dfrac{1+z}{1-z})^{1/4}\dfrac{\sqrt{ 1-z^2+i z\sqrt{1 - z^2}}}{1+z-i\sqrt{1 - z^2}}=1$ when it is assumed that $z\in R$ and $|z|<1$ and when I also plot the real and imaginary parts of it in that domain, it is indeed equal to $1$, but when I try to use
FullSimplify[expr, Assumptions -> {z \[Element] Reals && Abs[z] < 1}]
in order to try to get $1$, it gives back the same form of the expression.

So, what is the problem and how can I fix this?

EDIT: In Mathematica, I wrote this as

expr = (1 - I) ((1 + z)/(1 - z))^(1/4) Sqrt[
     1 - z^2 + I*z*Sqrt[1 - z^2]]/(1 + z - I*Sqrt[1 - z^2]);

And after getting the result, I used FullSimplify[%, Assumptions -> {z \[Element] Reals && Abs[z] < 1}]

Answer 1

expr = (1 - I) ((1 + z)/(1 - z))^(1/4) Sqrt[
     1 - z^2 + I*z*Sqrt[1 - z^2]]/(1 + z - I*Sqrt[1 - z^2]);

You can readily show that Im[expr] == 0, i.e., expr is real

Assuming[Element[z, Reals] && Abs[z] < 1, 
 Im[expr] // ComplexExpand[#, TargetFunctions -> {Re, Im}] & // FullSimplify]

(* 0 *)

The explicitly real form of expr is

expr2 = Assuming[Element[z, Reals] && Abs[z] < 1, 
  Re[expr] // ComplexExpand[#, TargetFunctions -> {Re, Im}] & // FullSimplify]

(* (1 + z + Sqrt[1 - z^2])/(Sqrt[2] Sqrt[(1 + z) (1 + Sqrt[1 - z^2])]) *)

Series shows that expr is almost certainly 1

Series[expr2, {z, 0, 100}]

Verifying that it is 1

Assuming[Element[z, Reals] && Abs[z] < 1, 
 expr2 == 1 // ComplexExpand[#, TargetFunctions -> {Re, Im}] & // 
  FullSimplify]

(* True *)

Answer 2

If you want to prove that something is constant, you can try differentiating it

Assuming[-1 < z < 1, FullSimplify[D[expr, z]]]
(* 0 *)

Answer 3

I will offer another, supplementary solution to the solutions given in other answers, but it is by no way convenient for doing calculations (especially long ones). We can just plot the function!
Plot[(1 - I) ((1 + z)/(1 - z))^(1/4) Sqrt[ 1 - z^2 + I*z*Sqrt[1 - z^2]]/(1 + z - I*Sqrt[1 - z^2]), {z, -3, 3}, PlotStyle -> {Red, Thick}]
which give the following plot:

where the graph is cut at $z=1$ because it then the expression becomes equal to $i$ (or, I).

Answer 4

If you think you know the answer, it is often easy to ask Mathematica to verify your suspicion

FullSimplify[ForAll[z, -1 < z < 1, expr == 1]]
(* True *)