7
$\begingroup$

EDIT: Solution can be found by hand quite easily. Don't know how to get Mathematica to do it though. Solution found by hand will give the curve, but with other curves too, which are not part of the actual solution.

I'm having a problem solving a 1st order nonlinear ODE analytically. DSolve finds all the solutions to the equation, however the actual solution -- which can be seen using NDSolve -- is made up of two of the solutions that were given by DSolve. When 'glued' together, these two solutions form a smooth curve which is the actual solution. I need to how to tell Mathematica to somehow obtain this solution.

I've simplified the equation a lot to remove unnecessary variables. Here's the equation now:

$$ y'(t) = \sqrt{\frac{1+y(t)}{y(t)^2}}$$

$$y(0)=1$$

eqn = y'[t] == Sqrt[(1 + y[t])/y[t]^2];

Here's my code for analytically solving and plotting the equation:

solE = DSolve[{eqn, y[0] == c1}, y, t];

Plot[Evaluate[y[t] /. solE /. c1 -> 1], {t, -3, 3}]

Here's the code for numerically solving and plotting the equation (Used ListLinePlot to avoid extrapolation due to division by 0 at around t = -0.4):

solN = NDSolve[{eqn, y[0] == 1}, y, {t, -5, 5}];

Show[ListLinePlot[y /. solN], PlotRange -> {{-3, 3}, {-1, 4}}]

As you can see from the plots below, the correct analytical solution (the positive curve that starts between $t=-1$ and $t=0$ at $y = 0$) is made up of two separate solutions (starts with the green curve, then transitions to red), glued together. How do I get Mathematica to return this 'composite curve' as the final solution?

Analytical solutions (left) and numerical solution (right):

Analytical and numerical plot

I would prefer a mathematical method of doing this, instead of just visually inspecting the two plots like I have. Previously, when I had multiple solutions, I successfully found the correct solution by verifying it using {eqn, initial condition} /. sol. However, it doesn't seem to work on this equation. For the original equation, the first solution returned true only for the initial condition, but the second solution returned false for both, so my method must be wrong.

Improve this question
$\endgroup$
3
  • $\begingroup$ DSolve offers more solutions than admissable, I think. Assuming y>-1(and real solutions y[t]) the ode should give y'[t]>0. Together with the condition y[0]==1only the branch remains which NDSolve returns! $\endgroup$
    – Ulrich Neumann
    Aug 19 '18 at 12:45
  • $\begingroup$ @UlrichNeumann I tried adding y > -1 as an assumption to DSolve, but then DSolve ran for over 5 minutes without any results. I thought this was because I had left out the condition y[0]==1 earlier on (I substituted 1 with 'c', or it would give missing solutions), but putting it back still yields the same result. I also tried assuming y[t] > -1 instead, but that doesn't have any effect, with or without specifying y[0]==1 inside DSolve. I also tried adding the assumption when evaluation the equation inside plot, but it didn't have any effect either? $\endgroup$
    – user55405
    Aug 19 '18 at 13:32
  • $\begingroup$ If I assume y[t] > -1 with the initial condition as y[0] == c, solutions are returned, but then when I try to plot it, nothing shows up. I also forgot to explicitly say in the question that y(0) = 1, edited now. $\endgroup$
    – user55405
    Aug 19 '18 at 13:41
3
$\begingroup$

The goal of this question is to reproduce the numerically determined curve,

eqn = y'[t] == Sqrt[(1 + y[t])/y[t]^2];
solN = NDSolve[{eqn, y[0] == 1}, y, {t, -5, 5}];
ListLinePlot[y /. solN, PlotRange -> {{-3, 3}, Automatic}, ImageSize -> Large, 
    AxesLabel -> {t, y}, LabelStyle -> {Bold, Black, Medium}]

enter image description here

by means of DSolve. The obvious solution is to try something like 

First[y /. solN][1/2];
solE2 = (DSolve[{eqn, y[1/2] == %}, y[t], t])

but DSolve returns solutions for both y'[t] == Sqrt[(1 + y[t])/y[t]^2] and y'[t] == - Sqrt[(1 + y[t])/y[t]^2]. Therefore, a brute force approach is necessary. Following the code in the question,

solE = (DSolve[{eqn, y[0] == c1}, y[t], t, Assumptions -> c1 > 0] /. c1 -> 1) 
    // Values // Flatten;
Plot[Evaluate@solE, {t, -3, 3}, ImageSize -> Large, AxesLabel -> {t, y}, 
    LabelStyle -> {Bold, Black, Medium}, PlotLabels -> Placed[Range[6], Above]]

enter image description here

we see that combining the right side of curve 1 and the left side of curve 2 will reproduce the numerical result. This is accomplished by ploting only the segments of these two curves for which the slope is positive.

Off[Greater::nord]
Plot[{If[(Chop[N[D[solE[[1]], t]] /. t -> t0]) > 0, Chop[N[solE[[1]] /. t -> t0]]], 
      If[(Chop[N[D[solE[[2]], t]] /. t -> t0]) > 0, Chop[N[solE[[2]] /. t -> t0]]]}, 
    {t0, -3, 3}, ImageSize -> Large, AxesLabel -> {t, y}, 
    LabelStyle -> {Bold, Black, Medium}]

enter image description here

which produces the desired result.

Addendum

In response to a comment below, the appropriate parts of the DSolve solution, as defined above, can be packaged in a function by

Clear[f];
f[t0_?NumericQ] := Module[
    {tm1 = Chop[N[D[solE[[1]], t] /. t -> t0]], 
     tm2 = Chop[N[D[solE[[2]], t] /. t -> t0]]}, 
    Piecewise[{{Chop[N[solE[[1]] /. t -> t0]], Im[tm1] == 0 && Re[tm1] > 0}, 
    {Chop[N[solE[[2]] /. t -> t0]], Im[tm2] == 0 && Re[tm2] > 0}}, Null]]
Improve this answer
$\endgroup$
1
  • $\begingroup$ Thank you, that worked perfectly. Is there a way of getting the correct solution as a piecewise function or equation? Previously, I had tried to find the maximum and minimum of the individual curves to find the domains of each function, then manually define the piecewise function. Wondering if there's a better way of doing this? $\endgroup$
    – user55405
    Aug 20 '18 at 10:16

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy