1
$\begingroup$

I'm working with the system of differential equations: $$\begin{align*} \left\{ \begin{array} { l l } { (u')^2 + (v')^2 = 1 } \\ {u'v'' - u''v' = -v' + u' } \end{array} \right. \end{align*}$$ Where $u, v:I \to \mathbb{R}$. Now, with a little bit of work, one can show that (below $c$ is a constant): $$u'(s) = \frac { 2 \sqrt { 2 } \operatorname { tanh } \left[ \frac { s } { \sqrt { 2 }}+c \right] - 2 \operatorname { tanh } \left[ \frac { s } { \sqrt { 2 } } +c\right ] ^ { 2 } } { 2 - 2 \sqrt { 2 } \tanh \left[ \frac { s } { \sqrt { 2 } } +c\right] + 2 \tanh \left[ \frac { s } { \sqrt { 2 } }+c \right] ^ { 2 } }$$

And if there was a nice primitive to this function, my life would be easier, since $v = \pm \int \sqrt{1-(u')^2} \ ds$. But unfortunately there isn't. My ultimate goal here is to plot the curve: $$X(s) = (\cos(u(s)),\sin(u(s)), v(s) )$$ But due to how nasty all these expressions become, it's proven to be a pretty hard task. Naturally I think the only way for me to really "see" this curve is using numerical resources, but I'm new to Mathematica (so I'm sorry if this question is too basic, I wouldn't know), so I don't know how to do that and I'd really appreciate some help.

$\endgroup$
  • 1
    $\begingroup$ One helpful starting point would be to provide Mathematica expressions. $\endgroup$ – b.gates.you.know.what Aug 15 '18 at 6:18
5
$\begingroup$

This system has an analytical solution. I will indicate it, but I can not prove that it is the only one. We start with the parametrization $u'=f=\cos(p(s)),v'=g=\sin(p(s))$. The first equation is automatically satisfied, and the second equation has an analytical solution that can be used to construct the curve $X(s)$:

f = Cos[p[s]];
g = Sin[p[s]];
f' = -Sin[p[s]]*p'[s];
g' = Cos[p[s]]*p'[s];
sol = DSolve[f*g' - g*f' + g - f == 0, p, s]

The solution of equation

{{p -> Function[{s}, -2 ArcTan[
      1 - Sqrt[2] Tanh[1/2 (Sqrt[2] s + Sqrt[2] C[1])]]]}}

Using this solution, we find functions $u,v$:

U = DSolve[u'[s] == Cos[p[s]] /. sol, u, s]
V = DSolve[v'[s] == Sin[p[s]] /. sol, v, s]

The solutions of equations:

{{u -> Function[{s}, 
    C[2] + 1/
      4 (2 ArcTan[1 - Sqrt[2] Tanh[(s + C[1])/Sqrt[2]]] + 
        Log[Cos[2 ArcTan[1 - Sqrt[2] Tanh[(s + C[1])/Sqrt[2]]]] + 
          Sin[2 ArcTan[1 - Sqrt[2] Tanh[(s + C[1])/Sqrt[2]]]]]) (Cos[
         2 ArcTan[1 - Sqrt[2] Tanh[(s + C[1])/Sqrt[2]]]] + 
        Sin[2 ArcTan[1 - Sqrt[2] Tanh[(s + C[1])/Sqrt[2]]]]) (-2 Cosh[
          Sqrt[2] (s + C[1])] + Sqrt[2] Sinh[Sqrt[2] (s + C[1])])]}}

{{v -> Function[{s}, 
    C[2] - 1/
      4 (2 ArcTan[1 - Sqrt[2] Tanh[(s + C[1])/Sqrt[2]]] - 
        Log[Cos[2 ArcTan[1 - Sqrt[2] Tanh[(s + C[1])/Sqrt[2]]]] + 
          Sin[2 ArcTan[1 - Sqrt[2] Tanh[(s + C[1])/Sqrt[2]]]]]) (Cos[
         2 ArcTan[1 - Sqrt[2] Tanh[(s + C[1])/Sqrt[2]]]] + 
        Sin[2 ArcTan[1 - Sqrt[2] Tanh[(s + C[1])/Sqrt[2]]]]) (-2 Cosh[
          Sqrt[2] (s + C[1])] + Sqrt[2] Sinh[Sqrt[2] (s + C[1])])]}}

The constant C[2] in solutions $u,v$ is not the same, but you can equate them, since this does not affect the shape of the curve $X(s)$:

X = Flatten[
  Simplify[{Cos[u[s]] /. U, Sin[u[s]] /. U, v[s] /. V}, 
   TimeConstraint -> 1]];
ParametricPlot3D[X /. {C[1] -> 0, C[2] -> 0}, {s, -10, 10}, 
 BoxRatios -> {1, 1, 1}, ColorFunction -> Hue]

fig1

$\endgroup$
  • $\begingroup$ Thank you! I appreciate it. $\endgroup$ – Matheus Andrade Aug 15 '18 at 11:19

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.