-3
$\begingroup$

How can I draw a picture like the following using Mathematica's graphics primitives?

picture

$\endgroup$
  • 4
    $\begingroup$ You should show your attempts and where you are getting stuck $\endgroup$ – Rojo Jan 18 '13 at 3:03
  • $\begingroup$ redeye, you'll note that this question has been down-voted by the community. If you answer some questions (thoughtfully) attitudes may be improved toward questions such as this one. Nevertheless showing your efforts always helps. $\endgroup$ – Mr.Wizard Jan 18 '13 at 10:01
13
$\begingroup$

Here's a start...

Manipulate[
 Show[poly[n], circ[n]],{{n, 5}, {5, 6, 7, 8, 9, 10}},
 Initialization :> (
  circ[n_] := 
  Graphics[{Arrowheads[.13], Thickness[.025], Circle[{0, 0}, 3], 
  Table[Arrow[
    BezierCurve[{3 {Cos@(t + 1.6 \[Pi]/n), Sin@(t + 1.6 \[Pi]/n)},
       2 {Cos@(t + .4 \[Pi]/n), Sin@(t + .4 \[Pi]/n)}, 
      1 {Cos@t, Sin@t}}]], {t, 0, 2 \[Pi], 2 \[Pi]/n}]}];
 poly[n_] := 
  Graphics[
  Polygon[(4/5) Partition[
    Flatten@Table[{{Cos@t, 
        Sin@t}, (2/3) {Cos@(t + \[Pi]/n), Sin@(t + \[Pi]/n)}}, {t,
        0, 2 \[Pi], 2 \[Pi]/n}], 2]]];)]

circle star

$\endgroup$
9
$\begingroup$

I'm bored:

s = .3 {{1, 0}, {.6, -.6}, {.3, -.2}};
k = {Arrowheads[.13], Thickness[.03], Circle[{0, 0}, .3], Arrow[BezierCurve[{s}]]};
Graphics[{Polygon[Table[.11 {Cos[t + Pi/17], Sin[t + Pi/17]}, {t, 0, 10 Pi, 10 Pi/8}]],             
                  Table[Rotate[k, 2 Pi i/8, {0, 0}], {i, 8}]}, 
                  PlotRange -> .32 {{-1, 1}, {-1, 1}}]

Mathematica graphics

$\endgroup$

Not the answer you're looking for? Browse other questions tagged or ask your own question.