Interactive plot labels

Question

This question was inspired by this answer.

Consider we have set of data:

data = RandomReal[1, {10, 5}]

Command which allows to plot arbitrary the columns is

Manipulate[
 ListLogPlot[TableOutputTotal[[All, {j, k}]], 
  Joined -> True], {{j, 1}, Range[10], SetterBar}, {{k, 2}, Range[10],
   SetterBar}]

Is there any way to introduce interactive plot legends? Say, if I plot columns 1 and 2, there will be a legend "Quantity 1", "Quantity 2", for 3 and 5 there will be "Quantity 3", "Quantity 5" and so on.

Answer 1

To have reproducible results you need to use SeedRandom prior to generating the random numbers.

SeedRandom[0];
data = RandomReal[1, {10, 5}];

There are only five columns so the controls should only go to five. To use PlotLegends you must plot each column separately. This requires you to Transpose the extracted data.

Manipulate[
 ListLogPlot[Transpose@data[[All, {j, k}]],
  Joined -> True,
  PlotLegends -> (Style[StringForm["Quantity ``", #], 14, Bold] & /@ {j, k})],
 Row[{
   Control[{{j, 1, Style["j", 14, Bold]}, Range[5], SetterBar}],
   Spacer[50],
   Control[{{k, 2, Style["k", 14, Bold]}, Range[5], SetterBar}]}]]