1
$\begingroup$
my3dobj = Image3D@Array[   Boole@FreeQ[Plus @@ Mod[PadLeft@IntegerDigits[{##} - 1, 3], 2, 1],      3 | 4] &, {3, 3, 3}^3]

Got this from here. I'd like to 3D print it.

Printout3D[Show@my3dobj]
Printout3D[my3dobj]

Tried solutions like Image3D[Raster3D[...]] and Show[] from here. Does not really work.

enter image description here

How can I export this to 3D printer using Printout3D[ ] ?

Thanks.

$\endgroup$
4
$\begingroup$

Printout3D needs a region not an image. I see a few ways to construct your region of interest. Here each subsequent solution is more roundabout than the last.

Method 1:

Printout3D[MengerMesh[3, 3]]

Method 2:

arr = Array[Boole@FreeQ[Plus @@ Mod[PadLeft@IntegerDigits[{##} - 1, 3], 2, 1], 3 | 4] &, {3, 3, 3}^3];

Printout3D[ArrayMesh[arr]]

Method 3:

Printout3D[ImageMesh[Image3D[arr]]]

All solutions output ‘Successful’ on my machine: enter image description here

$\endgroup$
1
$\begingroup$

Try

array = Array[
 Boole@FreeQ[
  Plus @@ Mod[PadLeft@IntegerDigits[{##} - 1, 3], 2, 1], 
  3 | 4
  ] &, {3, 3, 3}^3
 ];
Printout3D@ArrayMesh@array
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.