How can I use NSolve on my equation for an interval?

Question

I have two equations given by

P = E^((7 (-8 + 75 mu r) ArcTan[(-9 + 27 mu r + 2 Lambda r^2)/(
3 Sqrt[15 + mu r (26 - 121 mu r)])])/(4 Sqrt[15 + mu r (26 - 121 mu 
r)]))/(46656 r^18 (54 +r (-90 mu^2 r + Lambda r (-9 + Lambda r^2) +9 mu (-7+3 
Lambda r^2)))^6);

V = -((2592 E^((7 (8 - 75 mu r) ArcTan[(-9 + 27 mu r + 2 Lambda r^2)/(
 3 Sqrt[15 + mu r (26 - 121 mu r)])])/(4 Sqrt[15 + mu r (26 - 121 mu r)]))
r^19 (54 +r (-90 mu^2 r + Lambda r (-9 + Lambda r^2) +9 mu (-7 + 3 Lambda 
r^2)))^7));

Considering the following equations

dp = FullSimplify[D[P, Lambda]/D[V, Lambda]];
d2p = FullSimplify[D[dp, Lambda]/D[V, Lambda]];
rp = FullSimplify[dp - d2p];
RP = FullSimplify[rp /. {Lambda -> 4, q -> 1, mu -> 1}];

one can find that NSolve[RP == 0, r] takes a long time to be calculated (Indeed, I could not calculate it at all). Therefore, I want to calculate NSolve[RP == 0, r] for an interval, say 0<=r<=10. How can I do this? I will be thankful if someone helps.

Answer 1

P = E^((7 (-8 + 
          75 mu r) ArcTan[(-9 + 27 mu r + 
            2 Lambda r^2)/(3 Sqrt[15 + mu r (26 - 121 mu r)])])/(4 Sqrt[
         15 + mu r (26 - 121 mu r)]))/(46656 r^18 (54 + 
        r (-90 mu^2 r + Lambda r (-9 + Lambda r^2) + 
           9 mu (-7 + 3 Lambda r^2)))^6);

V = -((2592 E^((7 (8 - 
             75 mu r) ArcTan[(-9 + 27 mu r + 
               2 Lambda r^2)/(3 Sqrt[15 + mu r (26 - 121 mu r)])])/(4 Sqrt[
            15 + mu r (26 - 121 mu r)])) r^19 (54 + 
         r (-90 mu^2 r + Lambda r (-9 + Lambda r^2) + 
            9 mu (-7 + 3 Lambda r^2)))^7));

dp = FullSimplify[D[P, Lambda]/D[V, Lambda]];
d2p = FullSimplify[D[dp, Lambda]/D[V, Lambda]];
rp = FullSimplify[dp - d2p];
RP = FullSimplify[rp /. {Lambda -> 4, q -> 1, mu -> 1}];

Include the interval as a constraint

sol = NSolve[{RP == 0, 0 <= r <= 10}, r, Reals, WorkingPrecision -> 15]

(* {{r -> 0.169033833006918}, {r -> 0.415332388821552}} *)

Verifying,

RP /. sol

{0.*10^-15, 0.*10^-14}