1
$\begingroup$

I have a curve in a three dimensional space and I want to get the arc length function. So I defined the curve and its velocity and asked for the integral of the norm of its speed:

alpha[t_] := {Cosh[t], Sinh[t], t}
alphap[t_] := D[alpha[t], t]
Integrate[Norm[alphap[t]], t]

I got back

\[Integral]Sqrt[1 + Abs[Cosh[t]]^2 + Abs[Sinh[t]]^2] \[DifferentialD]t

I tried it with Rubi:

Import["C:\\Users\\genen\\Rubi4.15\\Rubi.m"]
Int[Norm[alphap[t]], t]

and got back:

 Int[Sqrt[1 + Abs[Cosh[t]]^2 + Abs[Sinh[t]]^2], t]

How can I get the system to give me the integral, or is it just that a closed form does not exist?

$\endgroup$
5
$\begingroup$

By default, MMA assumes expressions to be complex:

Norm[{x,y,z}]

Sqrt[Abs[x]^2 + Abs[y]^2 + Abs[z]^2]


If you look at Norm[alphap[t]], there's an Abs raised to the second power - hence, for real values, the Abs is redundant. Simply getting rid of it still requires an assumption that $t\in \mathbb{R}$, so let's go directly there:

Integrate[Norm[alphap[t]], t, Assumptions -> t ∈ Reals]

Sqrt[2] Sinh[t]


Also one could Simplify the integrand with the assumption:

Integrate[Simplify[Norm[alphap[t]], t ∈ Reals], t]

Sqrt[2] Sinh[t]

but it's to convoluted compared to Assumptions, and redundant.

| improve this answer | |
$\endgroup$
  • $\begingroup$ How to I get the "member of" symbol you used? (the backwards E) $\endgroup$ – Gene Naden Jul 18 '18 at 18:23
  • $\begingroup$ Element $\endgroup$ – corey979 Jul 18 '18 at 18:25
  • $\begingroup$ Also: <Esc> elem<Esc> $\endgroup$ – rhermans Jul 20 '18 at 7:55

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.