Extraction of array from NDSolve output

Question

I have got a system of differential equations. The system has $4$ variables. I am trying to plot trajectory of a particle outside a Kerr Black Hole. I have used Mathematica to calculate all the $4$ differential equation and now I am using NDSolve to calculate the trajectory numerically. The code is

kerr = NDSolve[{
   eqnr[s] == 0, eqnt[s] == 0, eqnϕ[s] == 0, eqnθ[s] == 0,
   r[0] == 5, θ[0] == Pi/Pi^2, t[0] == 0, ϕ[0] == 0,
   r'[0] == 0.01, θ'[0] == 0.003, 
   t'[0] == 0.01, ϕ'[0] == 0.003
   },
  {r, θ, ϕ, t}, {s, 0, 2}]

Initial conditions are randomly set. What this code gives as output are 4 arrays of coordinate $r$, $\theta$, $\phi$ and $t$. Now I want to covert this output from cartesian to spherical coordinate system. I know there is a command for doing such a thing but that will not be helpful here as to use that I need to extract the array computed by NDSolve and then insert into the function and then plot the parametric plot.

So my questions are: (i) Is there a direct way to do that? (ii) else how can I extract the computed array of coordinates? (The array that are outputted is shown as in the attached image)

Answer 1

The InterpolatingFunctions are Hermite splines of order 3. That is, their internal data consists of triplets of position, derivative, and second derivative. As an example, here the triples for r Partition[(r /. kerr[[1]])[[4, 3]], 3]. You would have to manipulate not only the positions but also first and second derivatives. It is easier to transform the trajectories to Cartesian coordinates this way. (Note that I use NDSolveValue only for convenience.)

kerr = s \[Function] Evaluate[
    NDSolveValue[{
      r''[s] == 0, t''[s] == 0, ϕ''[s] == 0, θ''[s] == 0,
      r[0] == 5, θ[0] == Pi/Pi^2, t[0] == 0, ϕ[0] == 0,
      r'[0] == 0.01, θ'[0] == 0.003, 
      t'[0] == 0.01, ϕ'[0] == 0.003
      },
     {r[s], θ[s], ϕ[s], t[s]}, {s, 0, 2}]
    ];

SphericalToCart = Block[{r, θ, ϕ, t},
   {r, θ, ϕ, t} \[Function] 
    Evaluate[
     Append[CoordinateTransform[ 
       "Spherical" -> "Cartesian", {r, θ, ϕ}], t]]
   ];

curve = s \[Function] SphericalToCart @@ kerr[s];

Answer 2

As I understand the author from another of his topics, he investigates the motion of particles in the Kerr metric. His question concerns the mapping of the trajectory of motion using NDSolve[] and ParametricPlot3D[]. I will give a sample code using his own code

 \[Rho] = r^2 + a^2 Cos[\[Theta]]^2;
\[CapitalDelta] = r^2 - 2 m r + a^2;

metric = {{-\[Rho]^2/\[CapitalDelta], 0, 0, 0}, {0, -\[Rho]^2, 0, 
    0}, {0, 0, -(r^2 + 
         a^2) Sin[\[Theta]]^2 - (2 m r a^2 Sin[\[Theta]]^4)/\[Rho]^2, \
(2 m a r)/\[Rho]^2 Sin[\[Theta]]^2}, {0, 
    0, (2 m a r)/\[Rho]^2 Sin[\[Theta]]^2, (1 - (2 m r)/\[Rho]^2)}};

inversemetric = Simplify[Inverse[metric]];
coord = {r, \[Theta], \[Phi], t};
christ[i_, j_, k_] := 
 christ[i, j, k] = 
  Simplify[Sum[
    1/2 inversemetric[[i, d]] (D[metric[[d, k]], coord[[j]]] + 
       D[metric[[d, j]], coord[[k]]] - 
       D[metric[[j, k]], coord[[d]]]), {d, 1, 4}]]
eq = Table[
   coord[[i]]'' + 
    Sum[christ[i, j, k] coord[[j]]' coord[[k]]', {j, 1, 4}, {k, 1, 
      4}], {i, 1, 4, 1}];
eqs = eq /. {r'' -> 
     r''[s], \[Theta]'' -> \[Theta]''[s], \[Phi]'' -> \[Phi]''[s], 
    t'' -> t''[s], 
    r' -> r'[s], \[Theta]' -> \[Theta]'[s], \[Phi]' -> \[Phi]'[s], 
    t' -> t'[s], 
    r -> r[s], \[Theta] -> \[Theta][s], \[Phi] -> \[Phi][s], 
    t -> t[s]};
EQ = Table[eqs[[i]] == 0 /. {m -> 1, a -> .3}, {i, 1, 4}];
kerr = NDSolve[{EQ, r[0] == 5, \[Theta][0] == Pi/2, 
    t[0] == 0, \[Phi][0] == 0, r'[0] == -0., \[Theta]'[0] == 0.00006, 
    t'[0] == 1, \[Phi]'[0] == 0.003}, {r, \[Theta], \[Phi], t}, {s, 0,
     2000}];
ParametricPlot3D[
 Evaluate[{Sqrt[a^2 + r[s]^2]*Sin[\[Theta][s]]*Cos[\[Phi][s]], 
     Sqrt[a^2 + r[s]^2]*Sin[\[Theta][s]]*Sin[\[Phi][s]], 
     r[s]*Cos[\[Theta][s]]} /. kerr /. a -> .3], {s, 0, 2000}, 
 ColorFunction -> Hue, AxesLabel -> {"x", "y", "z"}]