Issue with FrameTick marks in Mathematica 11.3

Question

Bug introduced in 11.3 or earlier and fixed on 12.0. (?)

---

For a while I have been using the same code to make figures with tickmarks pointing out from the axes away from the center of the figure.

Recently I noticed that in my upgrade to verision 11.3, the same code failed and now the tickmarks began to cross the frame axis. Here is an example:

I cannot seem to fudge the numbers to get the tick to match the axis frame. It is always either always just past or too long. Here is the code I am using currently.

ListPlot[{0.5, 0.5}, PlotRange -> {{0, 1}, {0, 1}}, 
 FrameTicksStyle -> Directive[{Black, Thick}]
 , Frame -> True
 , Joined -> False
 , AspectRatio -> 1
 , FrameStyle -> Thick
 , Axes -> False
 , BaseStyle -> {25, FontFamily -> "Arial"}
 , FrameLabel -> {Style["x", Black, 25, FontFamily -> "Arial"], 
   Rotate[Style["y", Black, 25, FontFamily -> "Arial"], -(Pi/2)]}, 
 FrameTicks -> {{Table[{0.2 i, 
      If[Round[i] == i, PaddedForm[0.2 i, {2, 1}], ""], {0, 
       If[Round[i] == i, 0.05, 0.025]}}, {i, 0, 10, 0.5}], 
    None}, {Table[{0.2 i, 
      If[Round[i] == i, PaddedForm[0.2 i, {2, 1}], ""], {0, 
       If[Round[i] == i, 0.05, 0.025]}}, {i, 0, 10, 0.5}], None}}]

Please help. Note I am using a MacOS High Sierra Version 10.13.5 ...

Answer 1

This is certainly a bug, please report to the tech support. Below are some comments and a workaround which I've found when playing with the Manipulate from the answer by Alexei Boulbitch (everything is checked with version 11.3 on Windows 7 x64).

At first, I should note that the presence or absence of the described issue depends on Magnification.

What is more important, the bug disappears if instead of positive value for tick length in the negative direction you specify negative value for tick length in the positive direction:

ListPlot[{0.5, 0.5}, PlotRange -> {{0, 1}, {0, 1}}, 
 FrameTicksStyle -> Directive[{Black, Thick}], Frame -> True, 
 Joined -> False, AspectRatio -> 1, FrameStyle -> Thick, 
 Axes -> False, BaseStyle -> {25, FontFamily -> "Arial"}, 
 FrameLabel -> {Style["x", Black, 25, FontFamily -> "Arial"], 
   Rotate[Style["y", Black, 25, FontFamily -> "Arial"], -(Pi/2)]}, 
 FrameTicks -> {{Table[{0.2 i, 
      If[Round[i] == i, PaddedForm[0.2 i, {2, 1}], 
       ""], {-If[Round[i] == i, 0.05, 0.025], 0}}, {i, 0, 10, 0.5}], 
    None}, {Table[{0.2 i, 
      If[Round[i] == i, PaddedForm[0.2 i, {2, 1}], 
       ""], {-If[Round[i] == i, 0.05, 0.025], 0}}, {i, 0, 10, 0.5}], 
    None}}]

Now we have a problem with incorrect distances of tick labels from the axes. We can fix them as follows:

ListPlot[{0.5, 0.5}, PlotRange -> {{0, 1}, {0, 1}}, 
 FrameTicksStyle -> Directive[{Black, Thick}], Frame -> True, 
 Joined -> False, AspectRatio -> 1, FrameStyle -> Thick, 
 Axes -> False, BaseStyle -> {25, FontFamily -> "Arial"}, 
 FrameLabel -> {Style["x", Black, 25, FontFamily -> "Arial"], 
   Rotate[Style["y", Black, 25, FontFamily -> "Arial"], -(Pi/2)]}, 
 FrameTicks -> {{Table[{0.2 i, 
      If[Round[i] == i, Row[{PaddedForm[0.2 i, {2, 1}], Spacer[12]}], 
       ""], {-If[Round[i] == i, 0.05, 0.025], 0}}, {i, 0, 10, 0.5}], 
    None}, {Table[{0.2 i, 
      If[Round[i] == i, 
       Grid[{{PaddedForm[0.2 i, {2, 1}]}}, 
        BaselinePosition -> Scaled[.6]], 
       ""], {-If[Round[i] == i, 0.05, 0.025], 0}}, {i, 0, 10, 0.5}], 
    None}}]

Answer 2

Try to play with this:

Manipulate[
 Plot[Cos[x], {x, 0, 10}, Frame -> True, 
  FrameTicks -> {{{0, 0 \[Degree], {a, b}}, {Pi, 
      180 \[Degree], {a, b}}, {2 Pi, 360 \[Degree], {a, b}}, {3 Pi, 
      540 \[Degree], {a, b}}}, {-1/2, 1/2}}], {a, -0.05, 
  0.05}, {b, -0.05, 0.05}, SaveDefinitions -> True]

and choose the values of a and b that best fit your aim.

Have fun!