5
$\begingroup$

The following expression is correctly simplified in versions 7, 10.2, 11.0

 FullSimplify[Exp[(9 Zeta[3]^(1/3) n^(2/3))/(4 Log[8]^(2/3)) + (3 c Log[4] Zeta[3]^(1/3) n^(1/3))/(2 Log[8]^(2/3)) - (c^2 Log[4]^2 Zeta[3]^(1/3))/(4 Log[8]^(2/3))] /. c -> ((1 - Log[2]) (3 Zeta[3])^(1/3))/(4  Log[2]^(5/3)), n > 0]

 (* E^(-((Zeta[3]^(1/3) (-36 n^(2/3) Log[2]^(4/3) + 12 n^(1/3) (-1 + Log[2]) Log[2]^(2/3) (3 Zeta[3])^(1/3) + (-1 + Log[2])^2 (3 Zeta[3])^(2/3)))/(16 3^(2/3) Log[2]^2))) *)

but in version 11.3 I get an error message

 (* FullSimplify::infd: Expression 4 n^(1/3) (-3 n^(1/3) Log[2]^(4/3) (3 Zeta[3])^(1/3)-(Log[8] Zeta[3])^(2/3)+Log[2] (Log[8] Zeta[3])^(2/3)) simplified to Indeterminate. *)

Why ? There is no reason for such message.

With Simplify instead FullSimplify is the calculation (in 11.3) correct (with a little longer output).

$\endgroup$
  • $\begingroup$ I get no errors on 10.4.1 for Microsoft Windows (64-bit), nor on 11.0.1 for Linux x86 (64-bit). $\endgroup$ – AccidentalFourierTransform Jun 20 '18 at 17:53
  • $\begingroup$ I get Indeterminate on MMA 11.2 Win7-64 $\endgroup$ – MarcoB Jun 20 '18 at 18:18
  • $\begingroup$ I also get Indeterminate on 11.1.1, Win10-64 $\endgroup$ – JungHwan Min Jun 20 '18 at 21:59
2
$\begingroup$
$Version

(* "11.3.0 for Mac OS X x86 (64-bit) (March 7, 2018)" *)

Using Simplify rather than FullSimplify

f[n_] = Simplify[
  Exp[(9 Zeta[3]^(1/3) n^(2/3))/(4 Log[8]^(2/3)) + (3 c Log[
         4] Zeta[3]^(1/3) n^(1/3))/(2 Log[8]^(2/3)) - (c^2 Log[4]^2 Zeta[
          3]^(1/3))/(4 Log[8]^(2/3))] /. 
   c -> ((1 - Log[2]) (3 Zeta[3])^(1/3))/(4 Log[2]^(5/3))]


(* E^(-((Zeta[3]^(
  1/3) (-144 n^(2/3) Log[2]^(10/3) + 
    24 n^(1/3) (-1 + Log[2]) Log[2]^(5/3) Log[4] (3 Zeta[3])^(
     1/3) + (1 + Log[2]^2 - Log[4]) Log[4]^2 (3 Zeta[3])^(2/3)))/(
 64 Log[2]^(10/3) Log[8]^(2/3)))) *)

Some alternate forms are

f2[n_] = f[n] // ExpandAll // FullSimplify

(* 2^(-((n^(1/3) (-1 + Log[2]) (3 Zeta[3])^(2/3))/(
  4 Log[2]^(7/3)))) E^(-(((-1 + Log[2])^2 Zeta[3])/(16 Log[2]^2)) + (
  3 n^(2/3) (3 Zeta[3])^(1/3))/(4 Log[2]^(2/3))) *)

or

f3[n_] = f[n] // ExpandAll // PowerExpand // Simplify

(* E^(((-1 - Log[2]^2 + Log[4]) (3/Log[8])^(2/3) Zeta[3] + 
 12 n^(2/3) Log[2]^(2/3) (3 Zeta[3])^(1/3) - 
 4 n^(1/3) (Log[2] (3 Zeta[3])^(2/3) - 
    3 3^(1/3) ((Log[2] Zeta[3])/Log[8])^(2/3)))/(16 Log[2]^(4/3))) *)

or

f4[n_] = f[n] // ExpToTrig // Simplify

(* Cosh[(1/(64 Log[2]^(10/3) Log[8]^(2/3)))
  Zeta[3]^(1/
    3) (-144 n^(2/3) Log[2]^(10/3) + 
     24 n^(1/3) (-1 + Log[2]) Log[2]^(5/3) Log[4] (3 Zeta[3])^(
      1/3) + (1 + Log[2]^2 - Log[4]) Log[4]^2 (3 Zeta[3])^(2/3))] - 
 Sinh[(1/(64 Log[2]^(10/3) Log[8]^(2/3)))
  Zeta[3]^(1/
    3) (-144 n^(2/3) Log[2]^(10/3) + 
     24 n^(1/3) (-1 + Log[2]) Log[2]^(5/3) Log[4] (3 Zeta[3])^(
      1/3) + (1 + Log[2]^2 - Log[4]) Log[4]^2 (3 Zeta[3])^(2/3))] *)

All of these expressions are equivalent to the result that you provided from earlier versions

f[n] == f2[n] == f3[n] == f4[n] == 
  E^(-((Zeta[3]^(1/3) (-36 n^(2/3) Log[2]^(4/3) + 
           12 n^(1/3) (-1 + Log[2]) Log[
              2]^(2/3) (3 Zeta[3])^(1/3) + (-1 + Log[2])^2 (3 Zeta[3])^(2/
               3)))/(16 3^(2/3) Log[2]^2))) // FullSimplify

(* True *)
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.