Trying to generate random even number

Question

I am trying to generate a random even number, and then try to write the list of primes that are composing it as Goldbach conjecture says.

It's just a test to learn how to use mathematica, so I would really appreciate comments.

I tried this:

f[i_]:=f[i]=Table[{i,1,100},i];

Generate an invisible table of integers up to 100. My teacher says you have to generate a list first to work with it.

a = If[f[i], Divisible[i,2],Print[i],Print[i+1]]

Here I attempted to print out only if the randomly generated integer was even.

DeleteCases[IntegerPartitions[a], If[a = PrimeQ, Print[a],]

Here I meant to tell Mathematica to sort out all the possibilities where a is composed of two primes, if not just do not print a.

This doesn't work of course. I tried to google the problem but I don't find something close enough.

Can you please help with that?

Answer 1

This should work:

(*generate a random integer between 3 and 100*)
n = 2*RandomInteger[{2, 50}]

(*list of primes smaller than the random integer n*)
listPrimes = Prime[Range[PrimePi[n]]]

(*list of pairs {prime,n-prime} for each prime in listPrimes*)
pairs = {#, n - #} & /@ listPrimes

(*select all the pairs where both the elements are primes and remove repetitions*)
result = DeleteDuplicates[Sort[#] & /@ Select[pairs, And @@ (PrimeQ[#]) &]]

EDIT: If you need the sum of 3 primes instead of two:

(*list of three primes {prime1,prime2,n-prime1-prime2} for each prime in listPrimes*)
tris = {#[[1]], #[[2]], n - #[[1]] - #[[2]]} & /@ Tuples[listPrimes, 2];

(*select all the three primes where all the elements are primes and remove repetitions*)
result= DeleteDuplicates[Sort[#] & /@ Select[tris, And @@ (PrimeQ[#]) && And @@ (Positive[#]) &]]

And you could represent your result as follows:

BarChart[result, ChartLayout -> "Stacked"]

I'll leave it with you for making it nice.