FindRoot does not work with Piecewise including complex-valued function

Question

Suppose we have the following Piecewise function:

gg[x_?NumericQ] := 
 Piecewise[{{x^4 - 6 x^3 + 5, x <= 1}, {8 x^2 - x^7, x > 1}}]

We can find the root of the function easily by:

FindRoot[gg[x], {x, 10}]
(* {x -> 1.51572} *)

The problem emerges when we make for example the second function complex:

gcom[x_?NumericQ] := 
 Piecewise[{{x^4 - 6 x^3 + 5, x <= 1}, {8 x^2 - x^7 I, x > 1}}]

In this case FindRoot does not work:

FindRoot[gcom[x], {x, 10}]

LessEqual::nord: Invalid comparison with 1.24121 -0.147854 I attempted.

Greater::nord: Invalid comparison with 1.24121 -0.147854 I attempted.

LessEqual::nord: Invalid comparison with 1.24121 -0.147854 I attempted.

Greater::nord: Invalid comparison with 1.24121 -0.147854 I attempted.

FindRoot::nlnum: The function value {\[Piecewise]   -3.813+2.96586 I    1.24121 -0.147854 I<=1
8.6317 -6.15431 I   1.24121 -0.147854 I>1
0   True

} is not a list of numbers with dimensions {1} at {x} = {1.24121 -0.147854 I}.

Note that outside the Piecewise function Mathematica can find the complex root:

FindRoot[8 x^2 - x^7 I, {x, 10}]

(* {x -> 1.44153 - 0.468382 I} *)

So my question is how can I find the complex roots of a complex-valued function in a Piecewise?

Answer 1

As I said in the comments, the solution to your FindRoot is a complex number. On the other hand, your function gcom only works when the input is a real number. This is what the error message is telling you. One possibility is to include a real check in your conditions (this is just one possibility). For example:

gcom[x_?NumericQ] := Piecewise[
    {{x^4 - 6 x^3 + 5, Element[x, Reals] && x <= 1}},
    8 x^2 - x^7 I (* otherwise *)
]

(another possibility as suggested by @Henrik in the comments is Re[x] <= 1)

Then:

FindRoot[gcom[x], {x,10}]

{x -> 1.44153 - 0.468382 I}