User Defined Color Scheme in a Package

Question

I have a package that is destined to plot stuff. The plots can have as many functions as the user wants so the variety of the color in the plots has to be enough. Which is why I created a new color gradient as it was explained in this question.

The code itself that adds the color gradient is

Unprotect[ColorData];
Clear[new2];
new2 = {{"Hueeee", "", {}}, {"Gradients"}, 
  1, {0, 1}, {Hue[0.33, 1, 0.58], Hue[0.6, 1, 0.9], 
   RGBColor[0.471412, 0.108766, 0.527016], Hue[0.9, 1, 0.9], 
   Hue[1, 1, 0.9], Hue[0.1, 1, 0.9]}, ""};
AppendTo[DataPaclets`ColorDataDump`colorSchemes, new2];
AppendTo[DataPaclets`ColorDataDump`colorSchemeNames, new2[[1, 1]]];

Its first output is

AppendTo::rvalue: DataPaclets`ColorDataDump`colorSchemes is not a variable with a value, so its value cannot be changed.
AppendTo::rvalue: DataPaclets`ColorDataDump`colorSchemeNames is not a variable with a value, so its value cannot be changed.

And the user-defined color data doesn't exist. If I run that code again it creates the color data as intended.

My question is, first, how can I make it so that running that code only once will create my color scheme? And second, how can I make it so the color scheme is added as soon as the package is imported? My understanding is that you put definition of functions inside Private, but I don't know if you actually write commands so that they are run and imported back to the notebook.

Thanks!

Answer 1

Your initial problem was due to the autoloading done by ColorData, as suggested by @MarcoB. The subsequent issue, which you only mention in the comments, is that both:

DataPaclets`ColorDataDump`colorSchemes
DataPaclets`ColorDataDump`colorSchemeNames

are also auto-loaded, and you need to finish the auto-loading before you try to append to the symbols. So, the following should do what you want:

(* force autoloading *)
ColorData[];
DataPaclets`ColorDataDump`colorSchemes;
DataPaclets`ColorDataDump`colorSchemeNames;

(* your code *)
Unprotect[ColorData];
Clear[new2];
new2 = {
    {"Hueeee", "", {}},
    {"Gradients"},
    1,
    {0,1},
    {
        Hue[0.33,1,0.58], Hue[0.6,1,0.9], RGBColor[0.471412,0.108766,0.527016],
        Hue[0.9,1,0.9], Hue[1,1,0.9], Hue[0.1,1,0.9]
    },
    ""
};
AppendTo[DataPaclets`ColorDataDump`colorSchemes,new2];
AppendTo[DataPaclets`ColorDataDump`colorSchemeNames,new2[[1,1]]];

I didn't get any errors, and:

ColorData["Gradients"]

{"AlpineColors", "Aquamarine", "ArmyColors", "AtlanticColors", "AuroraColors", "AvocadoColors", "BeachColors", "BlueGreenYellow", "BrassTones", "BrightBands", "BrownCyanTones", "CandyColors", "CherryTones", "CMYKColors", "CoffeeTones", "DarkBands", "DarkRainbow", "DarkTerrain", "DeepSeaColors", "FallColors", "FruitPunchColors", "FuchsiaTones", "GrayTones", "GrayYellowTones", "GreenBrownTerrain", "GreenPinkTones", "Hueeee", "IslandColors", "LakeColors", "LightTemperatureMap", "LightTerrain", "MintColors", "NeonColors", "Pastel", "PearlColors", "PigeonTones", "PlumColors", "Rainbow", "RedBlueTones", "RedGreenSplit", "RoseColors", "RustTones", "SandyTerrain", "SiennaTones", "SolarColors", "SouthwestColors", "StarryNightColors", "SunsetColors", "TemperatureMap", "ThermometerColors", "ValentineTones", "WatermelonColors"}

included your new gradient.