# Using Manipulate with ParametricPlot3D: buttons does not appear

I'm trying to use Manipulate with ParametricPlot3D, but the buttons does not appear. Someone has an idea why? Here's the code:

Remove["Global*"]
ClearAll["Global*"]

Manipulate[
ξ0 = 1 + 1*I ;
F1[x_, y_] :=
1/2*Re[(N[Log[x + I*y], 3] - (x + I*y)^4/4) - (N[Log[ξ0],
3] - (ξ0)^4/4)];
F2[x_, y_]   :=   -1/2*
Im[(N[Log[x + I*y], 3] + (x + I*y)^4/4) - (N[Log[ξ0],
3] + (ξ0)^4/4)] ;
F3[x_, y_]   :=    2*Re[(x + I*y)^2 - (ξ0)^2] ;

ParametricPlot3D[{F1[x, y], F2[x, y], F3[x, y]}, {x, a, b}, {y, c,
d}], {a, -2, -4, Appearance → "Open"}, {b, 2, 4,
Appearance → "Open"}, {c, -2, -4,
Appearance → "Open"}, {d, 2, 4,
Appearance → "Open"}] Here the problem is with the character you are using instead of Rule . I'm afraid ControlType -> Manipulator doesn't make a difference.

ToCharacterCode["\[RightArrow]"]
(* {8594} *)

ToCharacterCode["\[Rule]"]
(* {62754} *)


Your code works fine if you use -> instead of \[RightArrow].

Manipulate[
ξ0 = 1 + 1*I;
F1[x_, y_] :=
1/2*Re[(N[Log[x + I*y], 3] - (x + I*y)^4/4) - (N[Log[ξ0],
3] - (ξ0)^4/4)];
F2[x_, y_] := -1/2*
Im[(N[Log[x + I*y], 3] + (x + I*y)^4/4) - (N[Log[ξ0],
3] + (ξ0)^4/4)];
F3[x_, y_] := 2*Re[(x + I*y)^2 - (ξ0)^2];
ParametricPlot3D[{F1[x, y], F2[x, y], F3[x, y]}, {x, a, b}, {y, c, d}]
, {a, -2, -4, Appearance -> "Open"}
, {b, 2, 4, Appearance -> "Open"}
, {c, -2, -4, Appearance -> "Open"}
, {d, 2, 4, Appearance -> "Open"}
] By the way, your code would be better if you didn't redefine your functions each time Manipulate refreshes.

With[
{ξ0 = 1 + 1*I},
With[{
F1 = Function[
{x, y},
1/2*Re[(N[Log[x + I*y], 3] - (x + I*y)^4/4) - (N[Log[ξ0],
3] - (ξ0)^4/4)]
],
F2 = Function[
{x, y},
-1/2*
Im[(N[Log[x + I*y], 3] + (x + I*y)^4/4) - (N[Log[ξ0],
3] + (ξ0)^4/4)]
],
F3 = Function[
{x, y},
2*Re[(x + I*y)^2 - (ξ0)^2]
]
},
Manipulate[
ParametricPlot3D[
{
F1[x, y],
F2[x, y],
F3[x, y]
}
, {x, a, b}
, {y, c, d}
]
, {a, -2, -4, Appearance -> "Open"}
, {b, 2, 4, Appearance -> "Open"}
, {c, -2, -4, Appearance -> "Open"}
, {d, 2, 4, Appearance -> "Open"}
]
]
]
`
• Thanks to kglr, I tried what you suggested. Rhermans, you're right. It works, thanks for the tip. Jun 5, 2018 at 18:17