1
$\begingroup$
z = 1/3;
w1 = -6.507020907706122`*^-15 Cos[11.138034591281526` x] - 
   3.620441043680715`*^-15 Cosh[11.138034591281526` x] - 
   0.7169455947178107` Sin[11.138034591281526` x] - 
   0.01904792060284493` Sinh[11.138034591281526` x];
w2 = 0.38754182303955004` Cos[11.138034591281526` (-(1/3) + x)] - 
   0.3899009885381456` Cosh[11.138034591281526` (-(1/3) + x)] - 
   0.17709039562013243` Sin[11.138034591281526` (-(1/3) + x)] + 
   0.3899012654884649` Sinh[11.138034591281526` (-(1/3) + x)];
W = Piecewise[{{w1, x <= z}, {w2, x >= z}}]
UU = 2.51195553449907`*^-14 Cos[3.5811112720649185` y] + 
  0.005544404132968294` Sin[3.5811112720649185` y]
Plot[W, {x, 0, 1}]
Rotate[Plot[UU, {y, 0, 1}], \[Pi]/2]

I am getting two plots which are obtained from W and UU. W and UU are having a dependency on x and y respectively.W(x=z) and UU(y=1) takes the same value. I want to club these two plots and visualize the end results. I tried using Show but did not work.

T joint

$\endgroup$
  • 1
    $\begingroup$ Show[Plot[W, {x, 0, 1}, PlotStyle -> Red], ParametricPlot[{UU, y}, {y, -1, 1}, AspectRatio -> 1, GridLines -> {None, {1}}], PlotRange -> {-1, 1}]? $\endgroup$ – kglr May 23 '18 at 11:27
  • $\begingroup$ I am trying to plot a T shape, the horizontal line is governed by W and the vertical line is governed by UU, and x=z and y=1 is the attaching point of the horizontal line and verticle line. $\endgroup$ – acoustics May 23 '18 at 11:39
  • $\begingroup$ This looks like a beam vibration problem. Is w[x,t] transverse vibration and u[y,t] longitudinal vibration? If so how do you wish to plot the longitudinal vibration? Do you want this plotted as a transverse vibration? $\endgroup$ – Hugh Nov 19 '18 at 20:43
0
$\begingroup$

Perhaps something like:

wplot = Plot[W, {x, 0, 1}, PlotStyle -> Red];
uuplot = Plot[UU, {y, 0, 1}];

Show[MapAt[GeometricTransformation[#, TranslationTransform[{0, 1}]] &, wplot, 1], 
 MapAt[GeometricTransformation[#, Composition[TranslationTransform[{z + (W /. x->z), 0}],
     RotationTransform[Pi/2]]] &, uuplot, 1], 
 PlotRange -> {0, 1.5}, GridLines -> {{-z, z}, {1}}, 
 Ticks -> {{{z, Style["z", 20]}}, {{1, Style[1, 20]}}}]

enter image description here

Alternatively,

Show[MapAt[GeometricTransformation[#, TranslationTransform[{-z - (W /. x -> z), 1}]] &, 
    wplot, 1], 
  MapAt[GeometricTransformation[#, RotationTransform[Pi/2]] &, uuplot, 1], 
 PlotRange -> {0, 1.5},  GridLines -> {{-z, z}, {1}},
 Ticks -> {{{-z, Style["-z", 20]}, {z, Style["z", 20]}}, {{1, Style[1, 20]}}}]

enter image description here

$\endgroup$
  • $\begingroup$ uplot is crossing the zero , the w also shifted by z. I am trying to on the verticle line to translate by z amount. $\endgroup$ – acoustics May 23 '18 at 12:27

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.