prepending to elements of a list

Question

I have a list that consists of events occurring on certain dates of certain months. To simplify, the list looks like this:

list = {{"June","19","a"},{"b"},{"c"},{"August","2","d"},{"e"}}

I would like to prepend the month and date elements to each succeeding element until a new date is encountered, so as to make:

res = {{"June","19","a"},{"June","19","b"},{"June","19","c"},{"August","2","d"},{"August","2","e"}}

...and so forth. I'd like to avoid DateObjects and just work with strings.

I would like to generalize the question, by allowing the list to contain variable numbers of elements following the month/day elements:

list = {{"June","19","a","a1"},{"b","b2","b3","b4"},{"c"},{"August","2","d"},{"e","e1}} to give:


res = {{"June","19","a","a1"},{"June","19","b","b2","b3","b4"},{"June","19","c"},{"August","2","d"},{"August","2","e","e1}}

Answer 1

SequenceReplace[
  list,
  {{m_, d_, el_}, rest : {_} ...} :> 
   Sequence @@ Join[{{m, d, el}}, Join[{m, d}, #] & /@ {rest}]
  ]

{{"June", "19", "a"}, {"June", "19", "b"}, {"June", "19", "c"}, {"August", "2", "d"}, {"August", "2", "e"}}

For the modified list given in a comment below:

SequenceReplace[
 list,
 {{m_, d_, elems__}, rest : ({_} | {_, _}) ...} :> 
  Sequence @@ Join[{{m, d, elems}}, Join[{m, d}, #] & /@ {rest}]
 ]

And the most general version given can be solved like this:

months = Alternatives["January", "February", "Mars", "April", "May", 
   "June", "July", "August", "September", "October", "November", 
   "December"];

SequenceReplace[
 list,
 {{m : months, d_, elems__}, rest : {Except[months], ___} ...} :> 
  Sequence @@ Join[{{m, d, elems}}, Join[{m, d}, #] & /@ {rest}]
 ]

Answer 2

list = {{"June", "19", "a"}, {"b"}, {"c"}, {"August", "2", "d"}, {"e"}}
f[lst_] := With[{date = Most[lst[[1]]]},
  Prepend[Join[date, #] & /@ lst[[2 ;;]], First@lst]
  ]
f /@ Split[list, 1 == Length[#2] &]

Answer 3

ClearAll[f]
f = Module[{m = Split[#, 
        Not[MemberQ[DateString[{2018, #}, "MonthName"] & /@ Range[12], #2[[1]]]] &]}, 
    m[[;; , 2 ;;]] = Flatten /@ Thread[{#, #2}, List, {2}] & @@@ 
       Thread[{m[[;; , 1, ;; 2]], m[[;; , 2 ;;]]}]; 
    Join @@ m] &;

Examples:

list1 = {{"June", "19", "a"}, {"b"}, {"c"}, {"August", "2", "d"}, {"e"}};
list2 = {{"June", "19", "a", "a1"}, {"b", "b2", "b3", "b4"}, {"c"}, 
  {"August", "2", "d"}, {"e", "e1"}} ;

f /@ {list1, list2}

{{{"June", "19", "a"}, {"June", "19", "b"}, {"June", "19", "c"}, {"August", "2", "d"}, {"August", "2", "e"}},
{{"June", "19", "a", "a1"}, {"June", "19", "b", "b2", "b3", "b4"}, {"June", "19", "c"}, {"August", "2", "d"}, {"August", "2", "e", "e1"}}}